Описать, используя структуру данных запись, почтовую сортировку (город, улица, дом, квартира, кому, ценность). Составить

{
Описать, используя структуру данных запись, почтовую сортировку (город, улица,
дом, квартира, кому, ценность). Составить программу, определяющую:
 1) сколько посылок отправлено в г.Москву;
 2) сколько отправлено посылок ценностью выше 10 рублей;
 3) кому отправлено более 1 посылки. 
}
 
type
  // описание структуры данных записи "почта"
  TypMail = record
    City: string[20];    // город
    Street: string[20];  // улица
    House: integer;      // дом
    Apartment: integer;  // квартира
    Whom: string[20];    // кому
    Value: real;         // ценность
  end;
 
  // описание структуры данных записи для выполнения пункта задания №3
  TypDataWhom = record
    Whom: string[20];  // кому
    count: integer;    // количество почты
  end;
  
const
  Max = 100;  // максимальный размер массива
  
var
  mail: array[1..Max]of TypMail;  // массив данных записей
  n: integer;  // фактический размер массива mail
  dataWhom: array[1..Max]of TypDataWhom;  // данные для выполнения пункта задания №3
  m: integer;  // фактический размер массива dataWhom
  answer: integer;  // ответ от пользователя
  count1,count2: integer;  // счётчикм по пункту №1 и №2 соответственно
  flag: boolean;  // флаг
  i,j: integer;
  
begin
  // ввод данных
  n:=0;
  repeat
    // ввод очередной записи
    Inc(n);
    writeln;
    writeln('--- Запись №', n, ' ---');
    write('Город: ');
    readln(mail[n].City);
    write('Улица: ');
    readln(mail[n].Street);
    write('Дом: ');
    readln(mail[n].House);
    write('Квартира: ');
    readln(mail[n].Apartment);
    write('Кому: ');
    readln(mail[n].Whom);
    write('Ценность: ');
    readln(mail[n].Value);
    // вопрос к пользователю о продолжении ввода записей
    repeat
      writeln;
      write('Ещё создать запись? (1-да, 0-нет): ');
      readln(answer);
    until answer in[1,0];  // продолжать задавать вопрос до получения корректного ответа
  until answer=0;  // завершить вводить записи при ответе "нет"
  
  // вывод массива записей ввиде таблицы
    // вывод описания таблицы
  writeln;
  writeln('Таблица №1. Исходные данные.');
    // вывод шапки таблицы
  writeln('-------------------------------------------------------------------------------------------------');
  writeln('| Город              | Улица              | Дом      | Квартира | Кому               | Ценность |');
  writeln('-------------------------------------------------------------------------------------------------');
    // вывод тела таблицы
  for i:=1 to n do
  begin
    with mail[i] do
      writeln('|', City:20, '|', Street:20, '|', House:10, '|', Apartment:10, '|', Whom:20, '|', Value:10, '|');
    writeln('-------------------------------------------------------------------------------------------------');
  end;
  
  // вычисление...
    // инициализация
  count1:=0;
  count2:=0;
  m:=0;
    // анализ
  for i:=1 to n do
  begin
    // 1) сколько посылок отправлено в г.Москву;
    if mail[i].City='г.Москва' then
      Inc(count1);
    // 2) сколько отправлено посылок ценностью выше 10 рублей;
    if mail[i].Value>10 then
      Inc(count2);
    // 3) кому отправлено более 1 посылки. 
    flag:=false;  // допустим, запись не найдена
    for j:=1 to m do
      if dataWhom[j].Whom = Mail[i].Whom then
      begin
        Inc(dataWhom[j].count);  // подсчитать почту
        flag:=true;  // устанавливаем флаг, запись найдена
        break;  // завершить цикл сейчас
      end;
    if not flag then  // если запись не была найдена
    begin
      // то добавить её
      Inc(m);
      dataWhom[m].Whom:=mail[i].Whom;
      dataWhom[m].count:=1;
    end;
  end;
 
  // вывод результата
  // вывод массива записей ввиде таблицы
    // вывод описания таблицы
  writeln;
  writeln('Таблица №2. Таблица результата подсчёта количества почты к получению получателям.');
  writeln('            (для третьего пункта задания)');
    // вывод шапки таблицы
  writeln('-----------------------------------');
  writeln('| Кому               | Количество |');
  writeln('-----------------------------------');
    // вывод тела таблицы
  for i:=1 to m do
  begin
    with dataWhom[i] do
      writeln('|', Whom:20, '|', Count:12, '|');
    writeln('-----------------------------------');
  end;
  writeln;
  writeln('Ответы на три пункта задания.');
  writeln(' 1) сколько посылок отправлено в г.Москву;');
  writeln('Ответ: ', count1);
  writeln(' 2) сколько отправлено посылок ценностью выше 10 рублей;');
  writeln('Ответ: ', count2);
  writeln(' 3) кому отправлено более 1 посылки.');
  writeln('Ответ:');
  writeln('--- начало списка ---');
  for i:=1 to m do
    with dataWhom[i] do
      if count>1 then
        writeln('  ', Whom);
  writeln('--- конец списка ---');
  
  //
  writeln;
  writeln('===============================');
  writeln('Выполнение программы завершено.');
  readln;
end.