Шифровка и дешифрование методом Гронсфельда

uses FormsABC;
 
var 
  a := new Field('Код шифра');
  ok := new Button('Шифровать'); 
  dok := new Button('Дешифратор'); 
  tb: TextBox;
  tb2: TextBox;
 
procedure MyClick; // Шифрование
begin
  var Шифровка : (integer,integer) -> char := (a, b) -> 
    begin
     var d := b;
     case chr(a) of
       'A'..'Z': if a + b > ord('Z') then d -= 26;
       'a'..'z': if a + b > ord('z') then d -= 26;
       '0'..'9': if a + b > ord('9') then d -= 10;
       'А'..'Я': if a + b > ord('Я') then d -= 32;
       'а'..'я': if a + b > ord('я') then d -= 32;
     end;  
     Result := chr(a + d);
   end;
  var s:= tb.Text;
  var c := a.Text.ToCharArray.Select(t->t.todigit).Cycle.Take(s.Length).toArray;
  var res := s.ToCharArray.Select ((v,i) -> Шифровка(ord(v), c[i])).JoinToString;   
  tb2.AddLine(s + ' ++> ' + res);
end;
 
procedure MyClickd; // Дешифрование
begin
  var Дешифровка : (integer,integer) -> char := (a, b) -> 
   begin
     var d := b;  
     case chr(a) of
       'A'..'Z': if a - b < ord('A') then d -= 26;
       'a'..'z': if a - b < ord('a') then d -= 26;
       '0'..'9': if a - b < ord('0') then d -= 10;
       'А'..'Я': if a - b < ord('А') then d -= 32;
       'а'..'я': if a - b < ord('а') then d -= 32;
     end;  
     Result := chr(a - d);
   end;
  var s:= tb.Text;
  var c := a.Text.ToString.ToCharArray.Select(t->t.todigit).Cycle.Take(s.Length).toArray;
  var res := s.ToCharArray.Select ((v,i) -> Дешифровка(ord(v), c[i])).JoinToString;   
  tb2.AddLine(s + ' ---> ' + res);
end;
 
procedure InitControls;
begin
  MainForm.Title := 'Шифровка-Дешифровка';
  MainForm.SetSize(500,245);
  MainForm.CenterOnScreen;
  mainPanel.Dock := DockStyle.Left;
  mainPanel.Width := 110;
    a.Text := '0';
    ok.Width := 100;
    dok.Width := 100;
    ok.Click += MyClick;
    dok.Click += MyClickd;
  ParentControl := MainForm;
  tb := new TextBox;  
  tb.Dock := DockStyle.Top;
  tb2 := new TextBox;
  tb2.Dock := DockStyle.Bottom;
end;
 
begin
  InitControls;
end.

...  Шифровка(ord(v), c[i])).JoinIntoString;
 
.....   Дешифровка(ord(v), c[i])).JoinIntoString;