Решении задачи и блок-схема

uses graphABC;
var a,x0,y0,d,x1,y1:integer;
    r,f,xr,yr:real;
begin
repeat
write('Введите параметр а от 1 до 10 a=');
readln(a);
until a in [1..10];
clearwindow;
setwindowsize(500,500);
x0:=windowwidth div 2;
y0:=windowheight div 2;
//КООРДИНАТНАЯ  СЕТКА
d:=round((y0-40)/(round(a)));//шаг по оси радиуса в пикселях
setpencolor(clBlue);
setbrushstyle(bsClear);
for var i:=1 to round(a) do
 begin
  //рисуем окружности
  circle(x0,y0,i*d);
  //пишем шкалу
  textout(x0-i*d+5,y0+10,inttostr(i));
 end;
f:=30;//шаг по кругу=30 град
for var i:=1 to 12 do//делим на 12 частей
 begin
  //рисуем радиусы пунктиром
  Setpenstyle(psDash);
  x1:=x0+round((y0-40)*cos(i*f*pi/180));
  y1:=y0-round((y0-40)*sin(i*f*pi/180));
  line(x0,y0,x1,y1);
  //пишем подписи
  if (x1>=x0)and(y1<y0) then textout(x1+10,y1-15,inttostr(30*i))
  else if (x1>=x0)and(y1>=y0) then textout(x1+10,y1+10,inttostr(30*i))
  else if (x1<x0)and(y1<y0) then textout(x1-40,y1-15,inttostr(30*i))
  else if(x1<x0)and(y1>=y0)then textout(x1-40,y1+10,inttostr(30*i))
 end;
//рисуем осевые линии сплошной линией
Setpenstyle(psSolid);
line(10,y0,windowwidth-10,y0);
line(x0,0,x0,windowheight);
textout(x0+5,y0+10,'0');
textout(25,y0+10,'A');
//ГРАФИК
f:=0;//начальный угол
setpencolor(clRed);
setpenwidth(2);
while f<=2*pi do//полный оборот
 begin
    r:=a*sin(3*f);//уравнение в полярных координатах
    xr:=r*cos(f);//приведение к Декартовым
    yr:=r*sin(f);
    x1:=x0+round(d*xr);//приведение к экранным
    y1:=y0-round(d*yr);
    if f=0 then moveto(x1,y1)
    else lineto(x1,y1);
    f:=f+0.01;
 end;
end.