Написать программу Броуновского движения для курсовой

Uses GraphABC;
const MaxShar=50;
type shar = record
            x,y:integer; { текущие координаты шара }
            dx,dy:integer; { скорость. задается значениями
                    перемещения на каждом шаге (в точках) }
            end;
var i:byte;
    x,y,r:integer;
    shars: array[1..MaxShar] of shar; { массив шаров }
begin
randomize;
setwindowsize(500,500);
centerwindow;
r:=10;
setpenwidth(3);
for i:=1 to MaxShar do
with shars[i] do
 begin
  x:=7+r+random(500-2*r-14);
  y:=7+r+random(500-2*r-14);
  dx:=random(8);
  dy:=random(8);
 end;
lockdrawing;
repeat
clearwindow;
for i:=1 to MaxShar do
with shars[i] do
 begin
  x:=x+dx;
  if (x+r+dx>=493) or (x-r+dx<=7) then dx:=-dx;
  y:=y+dy;
  if (y+r+dy>=493) or (y-r+dy<=7) then dy:=-dy;
  setpencolor(clBlue);
  setbrushcolor(clBlue);
  circle(x,y,r);
 end;
setpencolor(clBlack);
setpenwidth(3);
moveto(5,5);
lineto(495,5);
lineto(495,495);
lineto(5,495);
lineto(5,5);
sleep(100);
redraw;
until false;
end.

Uses GraphABC;
const MaxShar=10;
type shar = class
  { переменные }
  x,y:integer; { текущие координаты шара }
  r:word;      { радиус }
  color:integer;  { цвет шара }
  dx,dy:integer; { скорость. задается значениями
                    перемещения на каждом шаге (в точках) }
  hits:set of byte; { множество шаров с которыми данный шар уже
  столкнулся и с которыми не надо обсчитывать столкновение еще раз }
  { методы }
  constructor initShar(x0,y0:integer; r0:integer; color0:integer; dx0,dy0:integer);
  procedure Move; { двигаем }
  procedure Show; { показываем }
  procedure CheckBorder; { проверяем на выход за границы экрана }
  procedure CheckHit(k:integer); { проверяем на столкновение с другим шаром }
  procedure revertXDirection; { поменять Х/Y-составляющую скорости }
  procedure revertYDirection; { на противоположную }
  procedure TurnAfterHit(k:integer); { вычислить новые значения
               скорости двух шаров после удара. Первый шар - шар
               данного объекта, второй - с индексом k в массиве }
  function Value:real; { вычислить объем шара. Нужно для вычисления
       скорости. Вообще-то там масса нужна, но учитывая, что плотность
       все-равно сократиться при делении, используем объем }
  {procedure PrintState;} { отладочные печати }
  end;
Procedure shar.Move;
  begin
  x:=x+dx;
  y:=y+dy;
  end;
Procedure shar.Show;
  begin
  setpenColor(color);
  setbrushcolor(color);
  circle(x, y, r);
 end;
procedure shar.revertXDirection;
  begin
  dx:=-dx;
  x:=x+dx;
  end;
procedure shar.revertYDirection;
  begin
  dy:=-dy;
  y:=y+dy;
  end;
Constructor shar.initShar(x0, y0 :integer; r0 :integer; color0 :integer; dx0, dy0 :integer);
  begin
  x:=x0;
  y:=y0;
  r:=r0;
  color:=color0;
  dx:=dx0;
  dy:=dy0;
  hits:=[];
  end;
procedure shar.CheckBorder;
  begin
  if (r+x>=windowwidth-1) or (x-r<=1) then revertXDirection;
  if (y+r>=windowheight-1) or (y-r<=1) then revertYDirection
  end;
var shars: array[1..MaxShar] of shar; { массив шаров }
procedure shar.TurnAfterHit(k:integer);
{ формулы для движения шаров взяты здесь:
  http://ferro.phys.msu.ru/prak/PDF/01-mechanics/07.pdf }
var m1, m2 :real;
    vx10,vy10,vx20,vy20:integer;
  begin
  m1 := Value;            { массы }
  m2 := shars[k].Value;
  vx10 := dx;             { начальные значения скоростей }
  vy10 := dy;
  vx20 := shars[k].dx;
  vy20 := shars[k].dy;
  { скорость первого шара после удара }
  dx := round((2*m2*vx20 + (m1-m2)*vx10)/(m1+m2));
  dy := round((2*m2*vy20 + (m1-m2)*vy10)/(m1+m2));
  { скорость второго шара после удара }
  shars[k].dx := round((2*m1*vx10 + (m2-m1)*vx20)/(m1+m2));
  shars[k].dy := round((2*m1*vy10 + (m2-m1)*vy20)/(m1+m2));
  end;
function shar.Value:real;
  begin { возвращает объем шара }
  Value:=4*Pi*r*r*r/3;
  end;
procedure shar.CheckHit(k:integer);
var i1:integer;
    dist:integer;
  begin
  for i1:=1 to MaxShar do if ((i1<>k) and not(k in hits)) then
    begin
    shars[i1].hits:=shars[i1].hits+[k];
    dist:=round(sqrt(sqr(1.0*x-shars[i1].x)+sqr(1.0*y-shars[i1].y)));
    if (dist<r+shars[i1].r) then
      begin
      TurnAfterHit(i1);
      CheckBorder;
      Move;
      shars[i1].CheckBorder;
      shars[i1].Move;
     { скорость задается значениеми dx и dy - шагами движения. Таким
      образом она дискретна. Момент столкновения определяется по
      расстоянию между шарами. Но запросто может случиться, что шары
      на каком-то шаге пересекутся и в этом случае необходимо их
      развести в разные стороны перед тем как высчитывать расстояние на
      следуещем шаге, иначе они могут пребывать в состоянии постоянного
      столкновения }
      dist:=round(sqrt(sqr(1.0*x-shars[i1].x)+sqr(1.0*y-shars[i1].y)));
      while (dist<r+shars[i1].r) do
        begin
        CheckBorder;
        Move;
        shars[i1].CheckBorder;
        shars[i1].Move;
        dist:=round(sqrt(sqr(1.0*x-shars[i1].x)+sqr(1.0*y-shars[i1].y)));
        end;
      end;
    end;
  end;
 
var i:integer;
    x,y,dx,dy:integer;
    r:integer;
 
begin
  rectangle(1,1,windowwidth-1,windowheight-1);
  { инициализация шаров случайным образом }
  for i:=1 to MaxShar do
    begin
    r:=20+random(10);
    shars[i]:=shar.initShar(1+r+random(windowwidth-2*r),
      1+r+random(windowheight-2*r),r,clrandom{1+random(GetMaxColor-1)},
      random(15)-7,random(12)-6);
    end;
   lockdrawing;
  { обсчитываем движение пока не нажата какая-либо клавиша }
  repeat
  clearwindow;
    { показываем все шары }
    for i:=1 to MaxShar do
      shars[i].Show;
    { временная задержка - установите свое значение для вашего компьютера }
    sleep(50);
    { просчитываем следующий шаг }
    for i:=1 to MaxShar do
     begin
      shars[i].Move;
      shars[i].CheckBorder;
      shars[i].CheckHit(i);
     end;
    for i:=1 to MaxShar do
    shars[i].hits:=[];
    redraw;
  until false;
end.