Увеличивающиеся круги в PascalABC.NET

uses GraphWPF;
const n=10;
type oType=class
  x,y,r,d:Real;
  procedure NewCircle;
  begin
    x:=Random(10.0,Window.Width-10);
    y:=Random(10.0,Window.Height-10);
    r:=Random(1.0,5);
    d:=Random(0.1,1.0);
  end;
  constructor:=NewCircle;
  procedure Step(o : array of oType);
  begin
    foreach var c in o do
      if c <> Self then
        if (x-c.x)**2+(y-c.y)**2 < (r+c.r)**2 then
          if r < c.r then
            begin
              NewCircle;
              Exit;
            end;
    Circle(x,y,r);
    r+=d;
    if r>min(Window.Width,Window.Height) then
      NewCircle;
  end;
  class function CreateArray(n : Integer) : array of oType;
  begin
    Result:=ArrGen(n,x->New oType);
  end;
end;
begin
  var o:=oType.CreateArray(n);
  BeginFrameBasedAnimation(()->foreach var c in o do c.Step(o));
end.

uses GraphABC;
const n=10;
type oType=class
  x,y:Integer;
  r,d:real;
  procedure NewCircle;
  begin
    x:=Random(10,Window.Width-10);
    y:=Random(10,Window.Height-10);
    r:=Random(1.0,5);
    d:=Random(0.1,1.0);
  end;
  constructor:=NewCircle;
  procedure Step(o : array of oType);
  begin
    foreach var c in o do
      if c <> Self then
        if (x-c.x)**2+(y-c.y)**2 < (r+c.r)**2 then
          if r < c.r then
            begin
              NewCircle;
              Exit;
            end;
    Circle(x,y,trunc(round(r)));
    r+=d;
    if (r>min(Window.Width,Window.Height)) or (x-r<0) or (y-r<0)
               or (x+r>Window.Width) or (y+r>Window.Height) then
      NewCircle;
  end;
  class function CreateArray(n : Integer) : array of oType;
  begin
    Result:=ArrGen(n,x->New oType);
  end;
end;
begin
  var o:=oType.CreateArray(n);
  while True do begin
    LockDrawing; // это чтобы было без мерцания.
    Window.Clear;
    foreach var c in o do c.Step(o);
    redraw;
    sleep(20)
  end;
end.