Расстановка ферзей на шахматном поле

var Up:Array[2..16] of Boolean;
var Down:Array[-7..7] of Boolean;
var Vr:Array[1..8] of Boolean;
var X:Array[1..8] of Integer;
var q:boolean;
var N,S:integer;
 
 
Procedure Hod(i,j:Integer);
begin
X[i]:=j;
Vr[j]:=False;
Up[i+j]:=False;
Down[i-j]:=False;
end;
 
Procedure o_hod(i,j:Integer);
begin 
Vr[j]:=True;
Up[i+j]:=True;
Down[i-j]:=True;
end;
 
Function D_hod(i,j:Integer):Boolean;
begin
D_hod:=Vr[j] and Up[i+j] And Down[i-j];
end;
 
Procedure Solve(i:Integer;Var q:Boolean);
var j:integer;
Begin
j:=0;
Repeat
Inc(j);
q:=false;
if D_hod(i,j) Then begin
Hod(i,j);
if i<8 Then Begin
Solve(i+1,q);
If Not q Then o_hod(i,j);
End
Else q:=True;
End;
Until q Or (j=8);
end;
 
begin 
.....
end.

var 
  n: integer; //размер стороны поля
  a: array[,] of integer; //поле, размер зададим позже
  
//проверяем клетку [i,j] можно ли на неё поставить фигуру ферзя
Function Proverka(i,j: integer): boolean;
begin  
  Result := true;
  for var step := 0 to i do begin
    if (j-step >= 0) and (a[i-step,j-step] = 2) then begin Result := false; exit end;
    if a[i-step, j] = 2 then begin Result := false; exit end;
    if (j+step < n) and (a[i-step,j+step] = 2) then begin Result := false; exit end
  end;  
end;
 
//ставим фигуру ферзя на линии line
Function fer(line: integer): boolean;
begin
  if line = n then begin Result := true; exit end; //все строки заполнены выходим из циклов без откатов
  for var col := 0 to n-1 do //перебираем все столбцы
    if Proverka(line,col) then begin 
       a[line, col] := 2; 
       Result := fer(line+1); //можно ли поставить фигуру на следующих линиях?
       If not Result then a[line,col] := 0 //если нелья то откат присваивания 2 (ферзя), а иначе ..
       else break;  //.. выйти из цикла
    end;
end;
 
begin //main
  n := ReadlnInteger('n =');
  a := new integer[n,n]; //задаем поле/матрицу размера n x n
  if not fer(0) then Print('нет решения') 
  else a.ConvertAll(t -> t=2 ? 'ф' : '_').Println //вывод матрицы на экран
end.

var 
  n: integer; //размер стороны поля
  a: array of integer; //расположение ферзей,индекc=ряд,знечение=столбец
  
//проверяем клетку [row,col] можно ли на неё поставить фигуру ферзя
Function Proverka(row,col: integer): boolean;
begin  
 Result := true;
 for var step := 0 to row do
   if (a[row-step] = col-step) or (a[row-step] = col) or (a[row-step] = col+step)
     then begin Result := false; break end;
end;
 
//ставим ферзя на поле в строке row
Function fer(row: integer): boolean;
begin
  if row = n then begin Result := true; exit end; //все фигуры расставлены выходим из циклов без откатов
  for var col := 0 to n-1 do //перебираем все столбцы
    if Proverka(row,col) then begin 
       a[row] := col; //в строке row задаем столбцец (col) с ферзем
       Result := fer(row+1); //можно ли разместить ферзей на последующих строках?
       If not Result then a[row] := 999 //если нельзя то откат (ферзь снова вне поля), а иначе ..
       else break;  //.. выйти из цикла
    end;
end;
 
begin
  n := ReadlnInteger('n ='); //задаем размер поля n*n
  a := |999|*n; //задаем значение положения ферзя в каждой строке по столбцу вне поля
  if not fer(0) then Print('нет решения')
  else MatrGen(n,n, (i,j)-> a[i]=j ? 'ф' : '_').Println(2)
end.