Создать список, элементами которого будут так же списки

type
  plist = ^tlist;
  tlist = { это - список по строке }
  record
    value: integer;
    next: plist;
  end;
  
  pvector = ^tvector;
  tvector = { это - список самих строк }
  record
    data: plist;
    next: pvector;
  end;
 
var
  f: text;
  pl, pl_first, pl_last: plist;
  pv, pv_first, pv_last: pvector;
  
  X: integer;
 
begin
  assign(f, 'm_list.txt');
  reset(f);
  
  pv_first := nil; pv_last := nil;
  
  while not seekeof(f) do
  begin
    pl_first := nil; pl_last := nil;
    
    while not seekeoln(f) do 
    begin
      read(f, X);
      
      new(pl);
      pl^.value := x;
      pl^.next := nil;
      
      if pl_first = nil then pl_first := pl
      else pl_last^.next := pl;
      pl_last := pl;
    end;
    readln(f);
    
    if pl_first <> nil then
    begin
      new(pv);
      pv^.data := pl_first;
      pv^.next := nil;
      
      if pv_first = nil then pv_first := pv
      else pv_last^.next := pv;
      pv_last := pv;
    end;
  end;
  
  close(f);
  
  { Теперь в pv_first хранится указатель на начало списка списков. Печатаем для теста }
  pv := pv_first;
  while pv <> nil do
  begin
    pl := pv^.data;
    while pl <> nil do
    begin
      write(pl^.value:4);
      pl := pl^.next;
    end;
    writeln;
    pv := pv^.next;
  end;
end.