Для функции y=f(x) получить таблицу значений и график этой функции на отрезке

uses
  GraphABC;
 
function F(const x: real): real;
begin
  if x <> 0 then f := 1/x/x-4*cos(pi * x)/sin(pi * x)
end;
 
const
  wLeft = 300; wRight = 50; //Отступы системы координат от края окна слева и справа
  wTop = 50; wBottom = 50; //Отступы сверху и снизу
 
///Декартова система координат
procedure CartesianCoordinateSystem(const x0, y0: integer; const a, b, fmin, fmax, dx, dy, Mx, My: real);
var
  i, x1, y1: integer;
  N: real;
  S: string;
begin
  Line(wLeft - 10, y0, WindowWidth - wRight + 30, y0);  //OX
  Line(x0, wTop - 30, x0, WindowHeight - wBottom + 10); //OY
  SetFontColor(clRed);
  SetFontSize(15);
  TextOut(WindowWidth - wRight + 30, y0 + 10, 'X');
  TextOut(x0 + 5, wTop - 40, 'Y');
  SetFontColor(clBlue);
  SetFontSize(10);
  { Засечки на оси OX: }
  for i := 1 to round((b - a) / dx) + 1 do 
  begin
    x1 := wLeft + trunc((i - 1) * Mx * dx);
    Line(x1, y0 - 3, x1, y0 + 3); //рисуем засечки на оси OX
    n := a + (i - 1) * dx;
    { Вертикальная сетка: }
    SetpenStyle(psDot);
    SetPenColor(RGB(200, 200, 200));
    if abs(N) > 1E-15 then Line(x1, wTop - 10, x1, WindowHeight - wBottom + 10);
    SetPenColor(RGB(0, 0, 0));
    SetpenStyle(psSolid);
    str(n:0:1, s);
    if N <> 0 then TextOut(x1 - TextWidth(S) div 2, y0 + 10, s);
  end;
  { Засечки на оси OY: }
  for i := 1 to round((fmax - fmin) / dy) + 1 do 
  begin
    y1 := WindowHeight - wBottom - trunc((i - 1) * My * dy);
    Line(x0 - 3, y1, x0 + 3, y1); //рисуем засечки на оси Oy
    n := fmin + (i - 1) * dy;
    { Горизонтальная сетка: }
    SetpenStyle(psDot);
    SetPenColor(RGB(200, 200, 200));
    if abs(N) > 1E-15 then Line(wLeft, y1, WindowWidth - wRight, y1);
    SetPenColor(RGB(0, 0, 0));
    SetpenStyle(psSolid);
    str(n:0:0, s);
    if N <> 0 then TextOut(x0 + 7, y1 - 8, s);
  end;
end;
 
///Границы интервала a и b подгоняем под dx и dy
procedure Interval(const d: real; var a, b: real);
begin
  if abs(frac(a / d)) > 1E-15 then a := trunc(a / d) * d - d; 
  if abs(frac(b / d)) > 1E-15 then b := trunc(b / d) * d + d
end;
 
///График функции в декартовых координатах
procedure Plot(const x0, y0: integer; const a, b, mx, my: real);
var
  x, y, PreY, NextY, dx: real;
  y1: integer;
  FirstPoint, YouCanDraw: boolean;
begin
  FirstPoint := false;
  x := a; dx := 1 / mx;
  try
    PreY := f(x)
  except
    x := x + dx
  end;
  while x < b do begin
    try
      x := x + dx;
      y := f(x);
      y1 := y0 - trunc(my * y);    
      YouCanDraw := (y1 >= wTop) and (y1 <= WindowHeight - wBottom){ and 
        (abs((f(x + dx) - y) / (y - PreY)) < 10)};
      if FirstPoint = false then begin 
        if YouCanDraw then begin
          MoveTo(x0 + trunc(mx * x), y1);
          FirstPoint := true
        end
      end
      else
        if YouCanDraw then LineTo(x0 + trunc(mx * x), y1)
        else FirstPoint := false;
      PreY := y;
    except
      x := x + dx;
      FirstPoint := false
    end
  end
end;
 
var
  a, b, mx, my, dx, dy, fmin, fmax: real;
  x0, y0: integer;
 
begin
  SetWindowTitle('  График функции: y = 1/x/x-4ctg(pi*x)');
  SetWindowSize(1200, 600);
  CenterWindow;
  a := -3; b := 3; dx := 0.5;
  Interval(dx, a, b);
  fmin := -10; fmax := 10; dy := 1;
  Interval(dy, fmin, fmax);
  mx := (WindowWidth - wLeft - wRight) / (b - a); //масштаб по Х
  my := (WindowHeight - wTop - wBottom) / (fmax - fmin); //масштаб по Y
  x0 := trunc(abs(a) * mx) + wLeft; y0 := trunc(abs(fmax) * my) + wTop; //начало координат
  CartesianCoordinateSystem(x0, y0, a, b, fmin, fmax, dx, dy, Mx, My); //Декартова система координат
  SetPenColor(clGreen);
  SetPenWidth(2);
  Plot(x0, y0, a, b, mx, my) //График функции в декартовых координатах
end.