Дана матрица: верно ли, что в каждой его строке встречаются все числа от 1 до N по одному разу?

const n=7;
var
a: array[1..n,1..n] of integer;
i,j: integer;
begin 
for i:=0 to n do
begin 
for j:=0 to n do
a[i,j]:=1+random(n)
end;
writeln(a[i,j])
end.

const
  MaxN=20;  {максимально допустимая размерность массива}
  
var
 a : array[1..MaxN,1..MaxN] of byte;
 n : integer;
 i,j,k : integer;
 NumbersInLine : set of byte;
 isGoodArray : boolean;
begin
 randomize;
 repeat
   WriteLn('Введите размерность массива  N от 1 до ',MaxN,' : '); Readln(n);
 until (n>=1) and (n<=MaxN);
 
 for i:=1 to n do
 begin
   for j:=1 to n do begin
      a[i,j]:=1+random(n);
      
      {для отладки первые две строки заполним всегда одинаково}
      if i=1 then a[i,j] := j; {первую строчку массива заполним числами
                                 в обратном порядке:  N.. 4 3 2 1}
      if i=2 then a[i,j] := n-j+1; {вторую строчку массива заполним числами
                                 в обратном порядке:  N.. 4 3 2 1}
      {----- конец фиксированного заполнения для отладки ---------}
                                 
      Write(a[i,j]:2,' ');
   end;
   writeln; {перевод на новую строку}
 end;
 
 {А теперь проверим массив на соотвествие заданию}
 isGoodArray := true; {перед проверкой считаем,что наш массив соотвествует требованиям}
 for i:=1 to n do begin
    NumbersInLine := []; {это для сохранения чисел, которые есть в строке}
    for j:=1 to n do begin
      if a[i,j] in NumbersInLine {если число уже есть в множестве, значит,
                                   такое число уже было в строке ранее,
                                   значит, условие задания НЕ выполняется!
                                   можно прерывать цикл! }
        then begin
          isGoodArray := false;
          Writeln;
          WriteLn('*Отладка: Облом произошёл на строке ',i,
                         ' число ',a[i,j],' встречается более одного раза!' );
          Break
        end
        else {такого числа ещё не было, занесём его в множестов}
          Include(NumbersInLine, a[i,j]);
    end;
    
    if isGoodArray then {если облома ещё не было, то}
       {в цикле проверим, все ли числа от 1 до n есть во множестве
        ВНИМАНИЕ! При заполнении массива случайными числами от 1 до N
           это можно не делать - числа либо повторятся (и облом произойдёт выше),
             либо будут строго по одному разу!}
       for k:=1 to n do
         if not (k in NumbersInLine) then begin
            isGoodArray := false;
            WriteLn('*Отладка 2: Облом произошёл на строке ',i,
               ' в строке нет, как минимум, числа ',k);
            Break;  {остальные числа уже не проверяем, раз одного нет,
                       то условие уже нарушено!}
         end;
 
    if not isGoodArray then Break; {всё, если условие нарушено,остальные строки
       матрицы проверять смысла нет, прерываем цикл i по строка !}
  end;
  
  if isGoodArray
    then WriteLn('Да, верно, что в каждой строке встречаются все числа от 1 до N по одному разу.')
    else WriteLn('Нет, не верно, что в каждой строке встречаются все числа от 1 до N по одному разу.');
end.