Изменить тип списка и выбрать случайный элемент из списка, который ввел пользователь

type
  //Тип основных данных.
  TData = Integer;
  //Тип указателя на элемент списка.
  TPElem = ^TElem;
  //Тип элемента списка.
  TElem = record
    Data: TData; //Основные данные.
    PNext: TPElem; //Указатель на следующий элемент списка.
  end;
  //Тип, описывающий однонаправленный список.
  TList = record
    PFirst, PLast: TPElem; //Указатели на первый и на последний элементы списка.
  end;
 
//Начальная инициализация списка. Внимание! Эту процедуру можно выполнять
//только в отношении пустого списка! Иначе - будут утечки памяти.
procedure Init(var aList: TList);
begin
  aList.PFirst := nil;
  aList.PLast := nil;
end;
 
//Добавление элемента в конец однонаправленного списка.
procedure Add(var aList: TList; const aData: TData);
var
  PElem: TPElem;
begin
  New(PElem);
  PElem^.Data := aData;
  PElem^.PNext := nil;
  if aList.PFirst = nil then
    aList.PFirst := PElem
  else
    aList.PLast^.PNext := PElem;
  aList.PLast := PElem;
end;
 
//Удаление элемента из однонаправленного списка по указателю на предыдущий элемент.
//Если указатель на предыдущий элемент равен NIL, то удаляется первый элемент списка.
procedure Del(var aList: TList; var aPPrev: TPElem);
var
  PDel: TPElem;
begin
  if aList.PFirst = nil then Exit;
  
  if aPPrev = nil then begin
    PDel := aList.PFirst;
    aList.PFirst := PDel^.PNext;
  end else begin
    PDel := aPPrev^.PNext;
    if PDel <> nil then aPPrev^.PNext := PDel^.PNext;
  end;
  if aList.PLast = PDel then aList.PLast := aPPrev;
  if PDel <> nil then Dispose(PDel);
end;
 
//Удаление однонаправленного списка из памяти и инициализация.
procedure Free(var aList: TList);
var
  PNext, PDel: TPElem;
begin
  PNext := aList.PFirst;
  while PNext <> nil do 
  begin
    PDel := PNext;
    PNext := PNext^.PNext;
    Dispose(PDel);
  end;
  Init(aList);
end;
 
//Распечатка однонаправленного списка.
procedure Print(const aList: TList);
var
  PElem: TPElem;
begin
  if aList.PFirst = nil then begin
    Writeln('Список пуст.');
    Exit;
  end;
  
  PElem := aList.PFirst;
  while PElem <> nil do 
  begin
    if PElem <> aList.PFirst then Write(', ');
    Write(PElem^.Data);
    PElem := PElem^.PNext;
  end;
end;
 
var
  N: TList;
  Data: TData;
  i, Code: Integer;
  S: String;
 
begin
  //Начальная инициализация списка.
  Init(N);
  repeat
    //Создание списока.
    Writeln('Создание списка 1.');
    Writeln('Прекратить ввод - пустая строка + Enter.');
    i := 0;
    repeat
      Write('Элемент ', i + 1, ': ');
      Readln(S);
      if S <> '' then begin
        Val(S, Data, Code);
        if Code = 0 then begin
          Inc(i);
          Add(N, Data);
        end else
          Writeln('Неверный ввод. Повторите.');
      end;
    until S = '';
    Writeln('Составлен список:');
    Print(N);
    Writeln;
       
    //Удаление списка из памяти.
    Free(N);
    Writeln('Список удалён из памяти. Работа завершена.');
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.