Нарисовать папоротник с помощью рекурсии

Uses 
  Crt,GraphABC;
var
  gr, gr1: integer;
  k, color: integer;
  newx, x, y, newy, a, b, r, c, d, e, f: real;
 
begin
  randomize;
  repeat
    r := random;
    if r <= 0.1 then
    begin
      a := 0;B := 0;c := 0;d := 0.16;f := 0;
    end
    else 
    begin
      if (r > 0.1) and (r <= 0.86) then
      begin
        a := 0.85;b := 0.04;c := -0.04;d := 0.85;f := 1.6;
      end 
      else 
      begin
        if (r > 0.86) and (r <= 0.93) then
        begin
          a := 0.2;b := -0.26;c := 0.23;d := 0.22;f := 1.6;
        end 
        else 
        begin
          a := -0.15;b := 0.28;c := 0.26;d := 0.24;f := 0.44;
        end;
      end;
    end;
    newx := (a * x) + (b * y);
    newy := (c * x) + (d * y) + f;
    x := newx;
    y := newy;
    putpixel(round(x * 64 + 350), round(530 - y * 48), clLightGreen);
    
  until keypressed;
  readkey;
end.

///Модуль для рисования фракталов семейства "Лист папоротника"
unit Paporotnik;
 
uses GraphABC;
 
type
 
  ///Настройки фрактала
  PaporotnikFractalInitalData = record
    data: array of array of real; 
    P0,P1,P2,P3:real;
  end;
  
  ///Фрактал "Лист папоротника"  
  PaporotnikFractal = class
  private
    data: array of array of real; 
    P0,P1,P2,P3:real;
  public
    constructor(initdata: PaporotnikFractalInitalData);
    begin
      data := initdata.data;
      P0 := initdata.P0;
      P1 := initdata.P1;
      P2 := initdata.P2;
      P3 := initdata.P3;
    end;
    procedure Draw(x0,y0,Iterations,Height,Brightness: integer; fast: boolean);
    begin
      var plotx, ploty, x, y : real;
      var Size := Height/11;
      var Width := Height div 2;
      var dx := Width div 2;
        var dc := Iterations div Brightness;
      if fast then
        LockDrawing;
      for var i:=1 to Iterations do begin
        var P := Random(100);    
        var rnd := P<P0 ? 0 : P<P1+P0 ? 1 : P<P2+P1+P0 ? 2 : 3;
        plotx := data[rnd,0]*x + data[rnd,1]*y;
        ploty := data[rnd,2]*x + data[rnd,3]*y + data[rnd,5];
        x := plotx;
        y := ploty;
        SetPixel(x0+Round(x*Size) + dx, y0+Height - Round(y*Size), GreenColor(byte(30 + (i div dc))));
      end;
      if fast then
        UnlockDrawing;      
    end;
  end;
 
end.

///Константы задающие фракталы
unit PaporotnikData;
 
uses Paporotnik;
 
var
  ///Папоротник с изогнутым листом
  PaprotnikData: PaporotnikFractalInitalData := (
    data: (( 0.0000,  0.0000,  0.0000,  0.1600, 0, 0.0000),
             ( 0.8500,  0.0400, -0.0400,  0.8500, 0, 1.6000),
             ( 0.1667, -0.2887,  0.2887,  0.1667, 0, 1.6000),
             (-0.1667,  0.2887,  0.2887,  0.1667, 0, 0.4400));
    P0: 3; 
    P1: 83;
    P2: 7; 
    P3: 7);
    
  ///Папоротник с прямым листом
  SimplePaprotnikData: PaporotnikFractalInitalData := (
    data: (( 0.00,  0.00, 0.00, 0.16, 0, 0.00),
             ( 0.85,  0.00, 0.00, 0.85, 0, 1.60),
             ( 0.20, -0.26, 0.23, 0.22, 0, 1.60),
             (-0.20,  0.26, 0.23, 0.22, 0, 1.60));
    P0: 3; 
    P1: 83;
    P2: 7; 
    P3: 7);
 
  ///Елка
  ElkaData: PaporotnikFractalInitalData := (
      data: (( 0.1000,  0.0000,  0.0000,  0.1600, 0, 0.0000),
           ( 0.8500,  0.0000,  0.0000,  0.8500, 0, 1.6000),
           (-0.1667, -0.2887,  0.2887, -0.1667, 0, 1.6000),
           (-0.1667,  0.2887, -0.2887, -0.1667, 0, 1.6000));
    P0: 1; 
    P1: 85;
    P2: 7; 
    P3: 7);
 
 
end.

//(c) DarkStar 2008
uses GraphABC, Paporotnik, PaporotnikData;
 
const 
  Iterations = 300000;         
  Height     = 600;            
  Fast       = false;
  Width      = Height div 2;        
  WindowWidth= Width * 3;        
  Brightness = 170;
 
var 
  Paprotnik := new PaporotnikFractal(PaprotnikData);
  SimplePaprotnik := new PaporotnikFractal(SimplePaprotnikData);
  Elka := new PaporotnikFractal(ElkaData);
 
begin
  InitWindow(200, 50, WindowWidth , Height, clBlack);
  Paprotnik.Draw(0, 0, Iterations, Height, Brightness, fast);
  SimplePaprotnik.Draw(Width, 0, Iterations, Height, Brightness, fast);
  Elka.Draw(Width*2, 0, Iterations, Height, Brightness, fast);
end.