Найти множество

type st = (t1, t2, t3, t4, t5, t6); //тип для элементов множества
     st_set = set of st; //тип для множества
 
//процедура для ввода множества
procedure read_set(var m: st_set; s: char); //формальные параметры: множество, название множества
var i, n: integer; //счётчик, количество элементов множества
    x: st; //элемент множества
    sx: string; //название элемента множества
    error: boolean; //флаг ошибки
begin
  m := []; //множество пока пустое
  repeat //ввод количества элементов множества с проверкой
    write('Количество элементов множества ', s, ' = ');
    readln(n);
    if (n < 0) or (n > 6) then writeln('Количество элементов должно быть в интервале [0..6], повторите ввод.')
  until (n >= 0) and (n <= 6);
  if n > 0 then writeln('Введите элементы множества:'); //если множество непустое, печатаем приглашение ввода множества
  for i := 1 to n do //цикл ввода элементов множества, если множество пустое, не выполнится ни разу
    repeat //цикл ввода очередного элемента множества
      write(i, ': '); //приглашение ввода элемента множества
      readln(sx); //читаем название элемента
      error := (length(sx) <> 2) or (sx[1] <> 't') or not (sx[2] in ['1'..'6']); //проверяем его на допустимость
      if error //если название недопустимое
        then writeln('Это не может быть элементом множества ', s, ', повторите ввод.') //то вводим элемент заново
        else begin //иначе (если название допустимое)
          x := st(ord(sx[2]) - ord('0') - 1); //вычисляем элемент по его названию
          error := x in m; //проверяем на принадлежность к множеству
          if error //если элемент уже есть в множестве,
            then writeln('Такой элемент уже есть в множестве ', s, ', повторите ввод.') //то вводим элемент заново
            else include(m, x) //иначе включаем элемент в множество
        end
    until not error //если нет ошибок, завершаем ввод очередного элемента
end;
 
//основная программа
var i: st; //счётчик
    comma: string; //строка для печати запятой между элементами множества
    a, b, c, d, y: st_set; //множества, результат будет в множестве "y"
 
begin
  writeln('Элементами множеств могут быть только элементы t1, t2, t3, t4, t5, t6.');
  //writeln('И больше никакие, прямо в таком виде их и вводить.');
  writeln('Мощность каждого множества равна 6');
  read_set(a, 'A'); //вводим множества
  read_set(b, 'B');
  read_set(c, 'C');
  read_set(d, 'D');
  y := (b + c * a + d) * b; //вычисляем результат
  write('Множество Y = (B + C * A + D) * B = ['); //начало печати результата
  comma := ''; //пока разделитель - пустая строка, разделитель (запятую) перед первым элементом печатать не надо
  for i := t1 to t6 do //цикл печати результата
    if i in y //если очередное значение счётчика принадлежит множеству
      then begin //то печатаем...
        write(comma); //печатаем разделитель
        write(i); //печатаем значение счётчика (равное элементу множества)
        comma := ', '; //следующим разделителем будет запятая
      end;
  writeln(']') //конец печати результата
end.