Определить тип множество массивами

const
  nMax = 500; //фактически, мощность множества
 
type MyRange = 1..nMax; //диапазон для множества
     MySet = array[MyRange] of boolean; //тип для множества
 
//очистка множества
procedure MyErase(var a: MySet);
var i: MyRange;
begin
  for i := low(MyRange) to high(MyRange) do a[i] := false
end;
 
//включение элемента во множество
procedure MyInclude(var a: MySet; x: MyRange);
begin
 a[x] := true;
end;
 
//исключение элемента из множества (это на всякий случай, можно убрать)
procedure MyExclude(var a: MySet; x: MyRange);
begin
  a[x] := false;
end;
 
//печать множества
procedure MyPrint(s: string; const a: MySet);
var i: MyRange;
begin
  writeln(s);
  for i := low(MyRange) to high(MyRange) do
    if a[i] then write(i :4);
  writeln
end;
 
//ввод множества
procedure MyRead(s: string; var a: MySet);
var n, i, x: integer;
begin
  writeln(s);
  repeat
    write('Количество элементов множества (не более ', high(MyRange) - low(MyRange) + 1, ')? ');
    readln(n)
  until (n >= 0) and (n <= high(MyRange) - low(MyRange) + 1);
  if n > 0 then writeln('Введите элементы множества (диапазон значений [', low(MyRange), '..', high(MyRange), ']):');
  for i := 1 to n do
    begin
      repeat
        write('Элемент', i, ' = ');
        readln(x);
        if (x < low(MyRange)) or (x > high(MyRange))
          then writeln('Элемент вне диапазона значений, повторите ввод')
          else if a[x]
            then writeln('Такой элемент уже есть во множестве, повторите ввод')
      until (x >= low(MyRange)) and (x <= high(MyRange)) and not a[x];
      MyInclude(a, MyRange(x))
    end
end;
 
//конъюнкция (умножение, пересечение) множеств
procedure MyConjunction(var a: MySet; const b, c: MySet);
var i: MyRange;
begin
  for i := low(MyRange) to high(MyRange) do a[i] := b[i] and c[i]
end;
 
//дизъюнкция (сложение, объединение) множеств
procedure MyDisjunction(var a: MySet; const b, c: MySet);
var i: MyRange;
begin
  for i := low(MyRange) to high(MyRange) do a[i] := b[i] or c[i]
end;
 
//разность множеств (не симметрическая)
procedure MyDifference(var a: MySet; const b, c: MySet);
var i: MyRange;
begin
  for i := low(MyRange) to high(MyRange) do a[i] := b[i] and not c[i]
end;
 
var a, b, c: MySet;
begin
  MyErase(a);
  MyErase(b);
  MyErase(c);
  MyRead('Ввод первого множества', b);
  MyRead('Ввод второго множества', c);
  writeln;
  MyPrint('Первое множество:', b);
  MyPrint('Второе множество:', c);
  MyConjunction(a, b, c);
  MyPrint('Конъюнкция множеств:', a);
  MyDisjunction(a, b, c);
  MyPrint('Дизъюнкция множеств:', a);
  MyDifference(a, b, c);
  MyPrint('Разность множеств:', a);
  readln
end.