GraphABC: как работает цикл while в конце кода?

while f<=2*pi do...

uses graphABC;
var x0,y0,i,x,y:integer;
    r,a,m,f:real;
    s:string;
begin
a:=2;
x0:=windowwidth div 2;
y0:=windowheight div 2;
m:=(x0-50)/(a*sqrt(2));
line(0,y0,2*x0,y0);   // Линия ось абсцисс
line(x0,0,x0,2*y0);   // Линия ось ординат
for i:=1 to 2*(trunc(a*sqrt(2))+1) do
 begin
  line(x0+round(i*m/2),y0-3,x0+round(i*m/2),y0+3);    // Деления на
  line(x0-round(i*m/2),y0-3,x0-round(i*m/2),y0+3);    // оси абсцисс.
  line(x0+3,y0-round(i*m/2),x0-3,y0-round(i*m/2));    // Деления на   
  line(x0+3,y0+round(i*m/2),x0-3,y0+round(i*m/2));    // оси ординат.
  str(i/2:0:1,s);
  textout(x0+round(i*m/2),y0+10,s);       // Нумерация на 
  textout(x0-round(i*m/2),y0+10,'-'+s);   // оси абсцисс.
  textout(x0-20,y0-round(i*m/2),s);       // Нумерация на 
  textout(x0-25,y0+round(i*m/2),'-'+s);   // оси ординат.
 end;
 
f:=0;
while f<=2*pi do
 begin
  if cos(2*f)>=0 then
   begin
    r:=a*sqrt(2*cos(2*f));
    x:=x0+round(r*cos(f)*m);
    y:=y0-round(r*sin(f)*m);
    setpixel(x,y,clRed);
   end;
  f:=f+0.001;
 end;
end.

f:=0; //начальный угол=0
while f<=2*pi do//пока он не больше 2pi
 begin
  if cos(2*f)>=0 then //если косинус не отрицательный
   begin
    r:=a*sqrt(2*cos(2*f));//вычисляем полярный радиус по уравнению кривой
    x:=x0+round(r*cos(f)*m); //переводим точку конца радиуса
    y:=y0-round(r*sin(f)*m);  //в декартовы координаты с учетом масштаба
    setpixel(x,y,clRed);  //и рисуем в них красную точку
   end;
  f:=f+0.001;//увеличиваем угол
 end;