Бинарные деревья. Нахождение высоты дерева

type
  tTree = ^pTree;
  pTree = record
    N, U : Integer;
    L, R : tTree;
  end;
 
procedure AddTree(N, U : Integer; var Tree : tTree);
begin
  if Tree = nil then
    begin
      New(Tree);
      Tree^.N := N;   Tree^.U := U;
      Tree^.L := nil; Tree^.R := nil;
    end
  else if Tree^.N > N then AddTree(N, U+1, Tree^.L)
  else if Tree^.N < N then AddTree(N, U+1, Tree^.R);
end;
  
function CreateTree : tTree;
var
  Root : tTree;
  M : Integer;
begin
  Write('M = '); ReadLn(M);
  Root := nil;
  repeat
    AddTree(Random(100), 0, Root);
    Dec(M);
  until M = 0;
  CreateTree := Root;
end;
 
procedure OutTree(Tree : tTree; Sp : Integer);
var i : Integer;
begin
  if Tree <> nil then
    begin
      OutTree(Tree^.R, Sp+1);
      for i := 1 to Sp*4 do Write(#32);
      WriteLn(Tree^.N, ' (', Tree^.U, ')');
      OutTree(Tree^.L, Sp+1);
    end;
end;
  
function HeightTree(Tree : tTree) : Integer;
var UL, UR : Integer;
begin
  if Tree^.L <> nil then UL := HeightTree(Tree^.L) else UL := Tree^.U;
  if Tree^.R <> nil then UR := HeightTree(Tree^.R) else UR := Tree^.U;
  if UL > UR then HeightTree := UL else HeightTree := UR;
end;
 
function MinTree(Tree : tTree) : tTree;
begin
  if Tree^.L <> nil then MinTree := MinTree(Tree^.L) else MinTree := Tree;
end;
  
function MaxTree(Tree : tTree) : tTree;
begin
  if Tree^.R <> nil then MaxTree := MaxTree(Tree^.R) else MaxTree := Tree;
end;
 
var
  Root : tTree;
  
begin
  Root := CreateTree;
  OutTree(Root, 0);
  WriteLn('Высота = ', HeightTree(Root));
  WriteLn('Уровень максимального элемента = ', MaxTree(Root)^.U);
  WriteLn('Уровень минимального элемента = ', MinTree(Root)^.U);
end.