Множества прямых

const
  ms = 300; //максимальная мощность множества
 
type
  sl = record a, b, c: real end; //тип - описание прямой (для множества M)
  pl = record p1, p2: sl end; //тип - описание двух прямых (для множеств W и P)
 
//функция вычисления угла между осью абсцисс и прямой
function angle(q: sl): real;
var
  t: real;
begin
  if q.b <> 0 then t := arctan(-q.a / q.b)
  else t := pi / 2;
  if t < 0 then t := t + pi / 2;
  angle := t
end;
 
//процедура печати уравнения одной прямой
procedure prn_s(q: sl);
begin
  writeln('(', q.a:15, ')x+(', q.b:15, ')y+(', q.c:15, ')=0')
end;
 
//процедура печати уравнений двух прямых (для множеств W и P)
procedure prn_p(q: pl);
begin
  prn_s(q.p1);
  prn_s(q.p2);
  writeln
end;
 
var
  m: array[1..ms] of sl;
  w, p: array[1..ms] of pl;
  t, ang: real;
  i, j, mm, wm, pm: integer;
  complete, error: boolean;
begin
  {mm := 0; wm := 0; pm := 0;}
  writeln('Введите коэффициенты прямых Ax+Bx+C=0,');
  writeln('окончание ввода - нулевые коэффициенты,');
  writeln('не более ', ms, ' прямых');
  error := false; //совпадающих и несуществующих прямых пока не найдено
  repeat //цикл ввода множества M
    if not error then inc(mm); //если найдена совпадающая прямая, или прямая не существует, повторяем ввод, иначе вводим следующую прямую
    with m[mm] do
      begin
        writeln('Прямая ', mm); //ввод коэффициентов
        write('A = ');
        readln(a);
        write('B = ');
        readln(b);
        write('C = ');
        readln(c);
        complete := (a = 0) and (b = 0) and (c = 0); //ввод закончен?
        if not complete then //если ввод не закончен, то
          begin
            error := (a = 0) and (b = 0); //если прямая не существует, то ошибка
            if not error then //если ошибки нет, то
              for i := 1 to mm - 1 do //цикл проверки уникальности прямой
                begin
                  t := a * m[i].b * m[i].c;
                  error := (t = m[i].a * b * m[i].c) and (t = m[i].a * m[i].b * c); //если прямые совпадают, то ошибка
                  if error then //если ошибка, то
                    begin //сообщаем о том, что прямые совпадают, и повторяем ввод
                      writeln('Есть совпадающая прямая:');
                      prn_s(m[i]);
                      writeln('Повторите ввод.');
                      break //досрочный выход из цикла проверки уникальности прямой
                    end
                end
            else writeln('Такая прямая не существует, повторите ввод');
          end
        else dec(mm) //иначе, если ввод закончен, то убираем из множества прямую с нулевыми коэффициентами
      end
  until complete or (mm = ms); //условие окончания ввода множества M
  writeln;
  writeln('Множество M:');
  if mm > 0 then for i := 1 to mm do prn_s(m[i]) //если множество M не пустое, то печатаем элементы множества M
  else writeln('<Пустое множество>'); //иначе печатаем, что множество пустое
  writeln;
  writeln('Mножество W:');
  for i := 1 to mm - 1 do     //вложенный цикл поиска ...
    for j := i + 1 to mm do  //... перпендикулярных прямых
      if m[i].a * m[j].a + m[i].b * m[j].b = 0 then //если прямые перпендикулярны, то
        begin
          inc(wm); //следующий номер элемента множества W
          if angle(m[i]) < angle(m[j]) then //если угол m[i] < угла m[j], то
            begin
              w[wm].p1 := m[i]; //первая прямая m[i]
              w[wm].p2 := m[j]; //вторая m[j]
            end
          else //иначе
            begin
              w[wm].p1 := m[j]; //первая прямая m[j]
              w[wm].p2 := m[i]; //вторая m[i]
            end;
          prn_p(w[wm]) //печатаем элемент множества W
        end;
  if wm > 0 then //если множество W не пустое, то
    begin
      writeln;
      repeat //вводим угол
        write('Введите угол в градусах [0..90): ');
        readln(ang)
      until (ang >= 0) and (ang < 90);
      ang := ang / 180 * pi //переводим угол в радианы
    end
  else writeln('<Пустое множество>'); //если множество W пустое, то сообщаем об этом
  writeln;
  writeln('Множество P:');
  for i := 1 to wm do //цикл поиска прямых с углом < ang
    if angle(w[i].p1) < ang then //если найдена прямая с углом < ang, то
      begin
        inc(pm); //следующий элемент множества P
        p[pm] := w[i]; //копируем найденный элемент из W в P
        prn_p(p[pm]) //печатаем элемент
      end;
  if pm = 0 then writeln('<Пустое множество>'); //если множество P пустое, то сообщаем об этом
  readln
end.