Изобразить на экране в аксонометрической проекции проволочный каркас правильной n угольной пирамиды

uses GraphABC;
 
const
  maxN = 10;
  a = 150;
  dist = 500;
  dt = 0.05;
 
type
  pType = record
    x, y, z : Real;
  end;
  tPoint = record
    x, y : Integer;
  end;
 
var
  n : Integer;
  p : array [0..maxN] of pType;
  v : pType;
  c : tPoint;
  t : Real;
 
procedure InitPoints;
var
  i : Integer;
  R : Real;
begin
  c.x := WindowWidth div 2;
  c.y := WindowHeight div 3;
  R := a / 2 / sin(pi/n);
  for i := 0 to n do
    begin
      p[i].x := R * cos(2*pi*i/n);
      p[i].y := 0;
      p[i].z := R * sin(2*pi*i/n);
    end;
  v.x := 0;
  v.y := a;
  v.z := 0;
end;
 
function xRotation(angle : Real; t : pType) : pType;
var
  cosA, sinA : Real;
begin
  cosA := cos(angle); sinA := sin(angle);
  Result.x := t.x;
  Result.y := t.y * cosA + t.z * sinA;
  Result.z := - t.y * sinA + t.z * cosA;
end;
 
function yRotation(angle : Real; t : pType) : pType;
var
  cosA, sinA : Real;
begin
  cosA := cos(angle); sinA := sin(angle);
  Result.x := t.x * cosA - t.z * sinA;
  Result.y := t.y;
  Result.z := t.x * sinA + t.z * cosA;
end;
 
function winCoord(t : pType) : tPoint;
begin
  Result.x := c.x + Round(t.x * dist / (t.z + dist));
  Result.y := c.y + a div 2 - Round(t.y * dist / (t.z + dist));
end;
 
procedure DrawLine(angle : Real; a, b : pType);
var
  pa, pb : tPoint;
begin
  pa := winCoord(xRotation(pi/4, yRotation(angle, a)));
  pb := winCoord(xRotation(pi/4, yRotation(angle, b)));
  Line(pa.x, pa.y, pb.x, pb.y);
end;
 
procedure DrawPiramide(angle : Real);
var
  i : Integer;
begin
  ClearWindow;
  for i := 0 to n-1 do
    begin
      DrawLine(angle, v, p[i]);
      DrawLine(angle, p[i], p[i+1]);
    end;
  Redraw;
end;
 
begin
  Read(n);
  if (n > 2) and (n < 11) then
    begin
      SetPenColor(rgb(0,0,0));
      InitPoints;
      LockDrawing;
      t := 0;
      repeat
        DrawPiramide(t);
        Sleep(5);
        t := t + dt;
      until False;
    end
  else
    WriteLn('Значение n может быть от 3 до ', maxN, ' !');
end.

function xRotation(angle : Real; t : pType) : pType;
var
  cosA, sinA : Real;
  p:pType;
begin
  cosA := cos(angle); sinA := sin(angle);
  p.x := t.x;
  p.y := t.y * cosA + t.z * sinA;
  p.z := - t.y * sinA + t.z * cosA;
  xRotation:=p;
end;