Найти член последовательности с заданным номером

var
  a, b, c, k: integer;
begin
  a := 3;
  b := 9;
  for k := 3 to 2021 do
    begin
      c := a - b;
      a := b;
      b := c
    end;
  write(c)
end.

##
  var a: BigInteger := 3;
  var b: BigInteger := 9;
  for var k := 3 to 2021 do if k.IsOdd then a -= b else b -= a;
  a.Print

##
  var a: BigInteger := 3;
  var b: BigInteger := 9;
  var s: string := '';
  for var k := 3 to 2021 do 
    begin
      if s = '' then
        begin
          if odd(k) then $'{k-2} {a} {b}'.Print
          else $'{k-2} {b} {a}'.Print;
          read(s);
          readln
        end;
      if k.IsOdd then a -= b else b -= a;
    end;
  a.PrintLn.ToString.Length.Print

const
  m = 423; {максимально необходимое количество десятичных разрядов результата}
type
  Big = array[1..m] of byte; {тип для чисел}
  
{процедура сложения длинных чисел x := x + y}
{d - длина результата}
procedure add(var x: Big; const y: Big; var d: integer);
var
  i: integer;
begin
  for i := 1 to d do {цикл по разрядам чисел}
    begin
      x[i] := x[i] + y[i]; {складываем разряды}
      if x[i] > 9 then {если есть перенос, то}
        begin
          dec(x[i], 10); {корректируем разряд}
          inc(x[i+1]) {распространяем перенос}
        end
    end;
  if (d < m) and (x[d+1] > 0) then inc(d) {корректируем количество разрядов результата}
end;
 
var
  a, b: Big; {массивы разрядов длинных чисел для нечётных и чётных членов последовательности}
  d, k: integer; {количество разрядов результата, счётчик,}
begin
  d := 1; {начальная длина результата}
  a[1] := 3; {первый член}
  b[1] := 9; {второй член}
  a[1] := b[1] - a[1]; {модуль третьего члена}
  for k := 4 to 2021 do {цикл вычисления модулей остальных членов}
    if odd(k) then add(a, b, d) else add(b, a, d);
  write('-');
  for k := m downto 1 do write(a[k]);
  readln
end.

const
  m = 10000; {максимально возможное количество десятичных разрядов результата}
type
  Big = array[1..m] of byte; {тип для чисел}
 
{процедура сложения длинных чисел x := x + y}
{d - длина результата}
procedure add(var x: Big; const y: Big; var d: integer);
var
  i: integer;
begin
  for i := 1 to d do {цикл по разрядам чисел}
    begin
      x[i] := x[i] + y[i]; {складываем разряды}
      if x[i] > 9 then {если есть перенос, то}
        begin
          dec(x[i], 10); {корректируем разряд}
          inc(x[i+1]) {распространяем перенос}
        end
    end;
  if (d < m) and (x[d+1] > 0) then inc(d) {корректируем количество разрядов результата}
end;
 
var
  a, b: Big; {массивы разрядов длинных чисел для нечётных и чётных членов последовательности}
  d, k, n: integer; {количество разрядов результата, счётчик, номер члена последовательности}
begin
  write('n = ');
  readln(n);
  d := 1; {начальная длина результата}
  a[1] := 3; {первый член}
  b[1] := 9; {второй член}
  a[1] := b[1] - a[1]; {модуль третьего члена}
  for k := 4 to n do {цикл вычисления модулей остальных членов}
    if odd(k) then add(a, b, d) else add(b, a, d);
  if n > 3 then {если номер члена больше 3, то}
    if odd(n) then {если номер члена нечётный, то}
      begin
        write('-'); {печатаем знак}
        for k := d downto 1 do write(a[k]) {печатаем разряды нечётного числа}
      end
    else {иначе (если номер члена чётный)}
      for k := d downto 1 do write(b[k]) {печатаем разряды чётного числа}
  else {иначе (если номер члена не больше 3)}
    if n = 1 then writeln(3) {если номер члена 1, то печатаем первый член}
    else {иначе}
      if n = 2 then write(9) {если номер члена 2, то печатаем второй член}
      else write(-6); {иначе печатаем третий член}
  readln
end.