Вычислить сумму ряда (ряд Тейлора для arctg(x))

@S3X · Регистрация: 13.11.2019

Студворк — интернет-сервис помощи студентам

При некоторых заданных x, N и E, определяемых вводом, вычислить:
a)сумму N слагаемых заданного вида;
b)сумму тех слагаемых, которые по абсолютной величине больше Е.
arctg(x)= x - (x^3)/3 + (x^5)/5 - (x^7)/7 + (x^9)/9 ... нашёл код только на с++

C++
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
#pragma hdrstop
#pragma argsused
 
#include <tchar.h>
#include <stdio.h>
#include <iostream>
#include <windows.h>
 
using namespace std;
int _tmain(int argc, _TCHAR* argv[])
{
int x=1,n,e;
float s,s1;
cin >> x >> n >> e;
for (int i = 1; i < n; i++) {
s=s+(x^(i+2))/(i+2);
if (((x^(i+2))/(i+2)) > e) {
s1=s1+(x^(i+2))/(i+2);
}
}
cout << "\n"<< " s = " <<s << " s1 = " << s1;
system("PAUSE");
return 0;
}
 
}

@Cyborg Drone · 06.10.2021, 01:10

Так себе программа.

Во-первых, вовсе не обязательно, что количество слагаемых, больших E, меньше, чем N, поэтому цикл for не применим.
Во-вторых, операция возведения в степень дорогостоящая, в данном случае лучше применить рекуррентное соотношение для числителя.
В-третьих, программа содержит ошибку: знаки слагаемых не чередуются.

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
var
  n, i: integer;
  x, xn, a, s, sn, se, e: real;
begin
  write('|x| <= 1;  x = ');
  readln(x);
  write('N > 0;  N = ');
  readln(n);
  write('E > 0;  E = ');
  readln(e);
  xn := x;
  i := 1;
  a := x;
  s := 0;
  repeat
    s := s + a;
    if abs(a) > e then se := s;
    if i = n then sn := s;
    inc(i);
    xn := -xn * x * x;
    a := xn / (2 * i - 1)
  until (i > n) and (abs(a) <= e);
  writeln('Сумма ', n, ' слагаемых равна ', sn);
  writeln('Сумма слагаемых, больших ', e, ' равна ', se);
  writeln('arctg(', x, ') = ', arctan(x))
end.

@S3X · 07.10.2021, 09:37 **[ТС]**

Пишет переполнение 21 строке, можно как-то пофиксить пробовал добавлением новой "b" переменной фиксить.

@Cyborg Drone · 07.10.2021, 11:47

Скорее всего, Вы ничего не знаете о ряде, который Вам дан в Вашем задании.
Область сходимости ряда Тейлора для arctg(x) - это x $https://www.cyberforum.ru/cgi-bin/latex.cgi?\tiny \in$ [-1; 1].
Ваш ряд в Википедии: Википедия - Ряд Тейлора - Ряды Маклорена некоторых функций, последний в списке тригонометрических функций. Обратите внимание на диапазон допустимых значений аргумента.

Немного не понятно? Тогда поясню подробнее "на пальцах":

Переполнение в 21 строке быть не может, возникает в 20 строке. Об этом ниже.

Числитель члена ряда суть показательная функция от i, а знаменатель - линейная функция от i.

Если Вы, вопреки приглашению в строке 5, вводите x < -1 или x > 1, то модули слагаемых, вместо того, чтобы с ростом i уменьшаться, будут только увеличиваться, поскольку с ростом i показательная функция растёт быстрее, чем линейная, поэтому условие выхода из цикла abs(a) ≤ e никогда не будет выполнено, и возведение в степень будет продолжаться до тех пор, пока переменная xn не переполнится (в строке 20, при этом программа не завершится аварийно, а в переменной xn будет специальное значение NaN, обозначающее бесконечность), после чего в строке 21 будет попытка разделить ∞ / (2i - 1), после чего программа завершится аварийно из-за недействительной операции деления бесконечности на число, и выдаст сообщение о переполнении.

Исправить указанное переполнение в пределах Вашего задания не представляется возможным, поскольку ряд с ограниченной областью определения Вам уже дан, а привести аргумент к нужному диапазону значений не получится.

Можно сделать проверку ввода, для того, чтобы некорректное значение нельзя было ввести. Для этого замените стоки 5..10 на

Pascal
5
6
7
8
9
10
11
12
13
14
15
16
  repeat
    write('|x| <= 1;  x = ');
    readln(x)
  until (x >= -1) and (x <= 1);
  repeat
    write('N > 0;  N = ');
    readln(n)
  until n > 0;
  repeat
    write('E > 0;  E = ');
    readln(e)
  until e > 0;

Если остались вопросы, пишите.

@S3X · 07.10.2021, 12:58 **[ТС]**

понял, спасибо

Новые блоги и статьи Все статьи Все блоги /
Камера Toupcam IUA500KMA Eddy_Em 12.02.2026 Т. к. у всяких "хикроботов" слишком уж мелкий пиксель, для подсмотра в ESPriF они вообще плохо годятся: уже 14 величину можно рассмотреть еле-еле лишь на экспозициях под 3 секунды (а то и больше),. . .	И ясному Солнцу zbw 12.02.2026 И ясному Солнцу, и светлой Луне. В мире покоя нет и люди не могут жить в тишине. А жить им немного лет.	«Знание-Сила» zbw 12.02.2026 «Знание-Сила» «Время-Деньги» «Деньги -Пуля»	SDL3 для Web (WebAssembly): Подключение Box2D v3, физика и отрисовка коллайдеров 8Observer8 12.02.2026 Содержание блога Box2D - это библиотека для 2D физики для анимаций и игр. С её помощью можно определять были ли коллизии между конкретными объектами и вызывать обработчики событий столкновения. . . .
SDL3 для Web (WebAssembly): Загрузка PNG с прозрачным фоном с помощью SDL_LoadPNG (без SDL3_image) 8Observer8 11.02.2026 Содержание блога Библиотека SDL3 содержит встроенные инструменты для базовой работы с изображениями - без использования библиотеки SDL3_image. Пошагово создадим проект для загрузки изображения. . .	SDL3 для Web (WebAssembly): Загрузка PNG с прозрачным фоном с помощью SDL3_image 8Observer8 10.02.2026 Содержание блога Библиотека SDL3_image содержит инструменты для расширенной работы с изображениями. Пошагово создадим проект для загрузки изображения формата PNG с альфа-каналом (с прозрачным. . .	Установка Qt-версии Lazarus IDE в Debian Trixie Xfce volvo 10.02.2026 В общем, достали меня глюки IDE Лазаруса, собранной с использованием набора виджетов Gtk2 (конкретно: если набирать текст в редакторе и вызвать подсказку через Ctrl+Space, то после закрытия окошка. . .	SDL3 для Web (WebAssembly): Работа со звуком через SDL3_mixer 8Observer8 08.02.2026 Содержание блога Пошагово создадим проект для загрузки звукового файла и воспроизведения звука с помощью библиотеки SDL3_mixer. Звук будет воспроизводиться по клику мышки по холсту на Desktop и по. . .

@S3X 1 / 1 / 1 Регистрация: 13.11.2019 Сообщений: 102
	07.10.2021, 09:37 [ТС]
	Пишет переполнение 21 строке, можно как-то пофиксить пробовал добавлением новой "b" переменной фиксить. 0

@S3X 1 / 1 / 1 Регистрация: 13.11.2019 Сообщений: 102
	07.10.2021, 12:58 [ТС]
	понял, спасибо 0

Вычислить сумму ряда (ряд Тейлора для arctg(x))

Решение