Получить в файле f последовательность матриц размера 4х4

program pas2;
 
Uses Crt;
 
label
     Exit_main_program;
 
type
    TRealValSymbols  = set of char;
    TProcessMode     = (pmRead, pmCreate);
    TProcessState    = (psSucces, psReadErr, psCreateErr);
 
const
     rows_qty          = 4;
     cols_qty          = 4;
     decimal_separator = '.';
 
     req_symbols:
       TRealValSymbols = ['0', '1', '2', '3', '4', '5',
                         '6', '7', '8', '9', '-',
                         decimal_separator];
 
     field_separator:
       Char            = ';';
 
     end_line:
       String[2]       = #13 + #10;
var
   FileNameSrc,
   FileNameDest: String;
   ProcState:    TProcessState;
 
procedure ProcessFile
(
  NameSrc,
  NameDst:     String;
  Mode:        TProcessMode;
  var Result:  TProcessState
);
var
   DataFileSrc:  File of Char;
   DataFileDest: File of Char;
   IsDataAvail:  Boolean;
   Row,
   Col,
   i:          Integer;
   strN:         String;
   chN:          Char;
 
begin
  Result := psSucces;
  Assign(DataFileSrc, NameSrc);
  {$I-}
  Reset(DataFileSrc);
  {$I+}
  if IOResult <> 0 then
    begin
    Result:=psReadErr;
    Exit;
    end;
  if Mode = pmCreate then
    begin
    Assign(DataFileDest, FileNameDest);
    {$I-}
    Rewrite(DataFileDest);
    {$I+}
    if IOResult <> 0 then
      begin
      Result:=psCreateErr;
      Exit;
      end;
    end;
 
  IsDataAvail := False;
  strN := '';
  Row := 0;
  Col := 0;
  while not Eof(DataFileSrc) do
    begin
    Read(DataFileSrc, chN);
    if (chN in req_symbols) then
      begin
      strN := strN + chN;
      IsDataAvail := True;
      end
    else
      begin
      if IsDataAvail then
        begin
        Col := Col + 1;
        case Mode of
          pmRead:
            Write(strN, field_separator);
          pmCreate:
            begin
            for i:=1 to Length(strN) do
              Write(DataFileDest, strN[i]);
            Write(DataFileDest, field_separator);
            end
        end; { case }
 
 
        if ((Col mod cols_qty) = 0) then
          begin
          case Mode of
            pmRead:
              WriteLn;
            pmCreate:
              begin
              Write(DataFileDest, end_line[1]);
              Write(DataFileDest, end_line[2]);
              end;
          end; { case }
          Col := 0;
          Row := Row + 1;
          if ((Row mod rows_qty) = 0) then
            begin
            case Mode of
              pmRead:
                WriteLn;
              pmCreate:
                begin
                Write(DataFileDest, end_line[1]);
                Write(DataFileDest, end_line[2]);
                end;
            end; { case }
            Row := 0;
            end;
          end;
        strN := '';
        IsDataAvail := False;
        end;
      end;
    end;
 
  Close(DataFileSrc);
 
  if Mode = pmCreate then
    Close(DataFileDest);
 
end;
 
begin
  ClrScr;
 
  Write('Введите имя входного файла: ');
  ReadLn(FileNameSrc);
 
  Write('Введите имя выходного файла: ');
  ReadLn(FileNameDest);
 
  WriteLn('Чтение исходного файла . . . ');
  WriteLn;
 
  ProcessFile(FileNameSrc, FileNameDest, pmRead, ProcState);
 
  WriteLn('Создание выходного файла . . . ');
 
  ProcessFile(FileNameSrc, FileNameDest, pmCreate, ProcState);
 
  case ProcState of
    psReadErr:
      begin
      WriteLn;
      WriteLn('Ошибка файлового ввода-вывода.');
      WriteLn('Входной файл не сущствует.');
      goto Exit_main_program;
      end;
    psCreateErr:
      begin
      WriteLn;
      WriteLn('Ошибка файлового ввода-вывода.');
      WriteLn('Выходной файл не создан.');
      goto Exit_main_program;
      end;
    end;
  WriteLn('Выходной файл создан.');
 
  Exit_main_program:;
 
  WriteLn;
  WriteLn('Для продолжения нажмите любую клавишу . . .');
  ReadKey;
 
end.