Определить, на какую букву начинается больше всего слов в предложении?

program Project1;
 
const
  //Множество разделителей.
  D = ['.', ',', ':', ';', '!', '?', '-', ' ', #9, #10, #13];
var
  Arr : array[#0..#255] of Integer;
  S : String;
  Ch : Char;
  i, Len, Mx : Integer;
begin
  repeat
    Writeln('Задайте строку:');
    Readln(S);
 
    //Обнуляем элементы массива.
    for Ch := #0 to #255 do Arr[Ch] := 0;
 
    //Собираем статистику по первым буквам в словах.
    Len := Length(S);
    Mx := 0;
    for i := 1 to Len do begin
      //Пропускаем разделители.
      if S[i] in D then Continue;
      //Отслеживаем начало слова, изменяем статистику и ищем наибольшее
      //число присутствий.
      if (i = 1) or (S[i - 1] in D) then begin
        Inc( Arr[S[i]] );
        if Arr[S[i]] > Mx then Mx := Arr[S[i]];
      end;
    end;
 
    if Mx > 0 then begin
      Writeln('Все буквы, с которых начинается больше всего слов в тексте:');
      i := 0;
      for Ch := #0 to #255 do begin
        if Arr[Ch] <> Mx then Continue;
        Inc(i);
        if i > 1 then Write(', ');
        Write(Ch);
      end;
      Writeln;
    end else
      Writeln('В тексте нет слов.')
    ;
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.