Каждый робот живет 3 года после сборки. Сколько роботов будет через N лет?

@Akcent2 · Регистрация: 27.11.2011

Студворк — интернет-сервис помощи студентам

Сообщество роботов живет по следующим законам: один раз в год они объединяются а полностью укомплектованные группы по 3 или 5 роботов(причем число групп из 3-х роботов-максимально возможное). За год группа из 3-х роботов собирает 5 новых роботов, а группа из 5 роботов - 9 новых роботов.
Каждый робот живет 3 года после сборки. Известно начальное количество роботов(k>7, все они только что собраны). Определить сколько роботов будет через N лет.

@Cyborg Drone · 24.07.2014, 15:03

Не по теме:

И я ещё немного побуду на форуме, если что, пишите, пока я на работу не упылил...

@CrazzyBeer · 24.07.2014, 15:05

Я пока другую буду решать. Жду ваших вариантов, если будет желание

@Cyborg Drone · 24.07.2014, 15:10

Не по теме:

Сообщение от CrazzyBeer

Вот

Ну да, всё по правилам. В принципе, я всё пояснил. Делается такая цензура для того, чтобы не было потери контента на сторонних ресурсах. Представьте, кто-нибудь в будущем попытается перейти по ссылке, а она уже битая, к примеру, сайт приказал долго жить. Правда, обидно будет кто-нибудю?

Добавлено через 2 минуты

Не по теме:

Задачка интересная. Ночером постараюсь с нею разобраться.

@Ромаха · 25.07.2014, 09:56

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
var
    k, n, p, p1, p2, p3, i : LongInt;
 
begin
    Reset(input, 'input.txt');
    Rewrite(output, 'output.txt');
 
    ReadLn(k, n);
    p1 := k; p2 := 0; p3 := 0;
    for i := 1 to n-1 do begin
        p := (p1+p2+p3) div 5*9;
        if (p1+p2+p3) mod 5 = 3 then Inc(p, 5);
        if ((p1+p2+p3) mod 5 = 1) and (p1+p2+p3 > 1) then Inc(p);
        if (p1+p2+p3) mod 5 = 4 then begin
            if p1+p2+p3 > 4 then Inc(p,6)
            else Inc(p, 5)
        end;
        if ((p1+p2+p3) mod 5 = 2) and (p1+p2+p3 > 2) then
            if p1+p2+p3 > 10 then Inc(p, 2)
            else Inc(p, 1);
        p3 := p2; p2 := p1; p1 := p
    end;
    WriteLn(p1+p2+p3)
end.

@Cyborg Drone · 25.07.2014, 16:45

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
var k, n, i, t, p: longint;
    a: array [0..2] of longint;
 
begin
  assign(input, 'input.txt'); reset(input);
  assign(output, 'output.txt'); rewrite(output);
  read(k, n);
  if k >= 3
    then begin
      a[0] := k; a[1] := 0; a[2] := 0;
      for i := 1 to n - 1 do
        begin
          if (k < 8) and (k <> 5)
            then begin
              t := k div 3;
              p := 0
            end
            else begin
              t := k mod 5 * 2 mod 5;
              p := k div 5 - t shr 1
            end;
          a[i mod 3] := 5 * t + 9 * p;
          k := a[0] + a[1] + a[2];
        end
    end
    else if n >= 4 then k := 0;
  write(k)
end.

@CrazzyBeer · 20.08.2014, 18:10

Огромное спасибо, код рабочий. Осталось только понять. К месту было быть хоть чуть чуть объяснений метода

@Cyborg Drone · 22.08.2014, 15:51

Сообщение от CrazzyBeer

К месту было быть хоть чуть чуть объяснений метода

Ну, какой, к лешему, метод? Хотя, нет, метод таки есть. Нахождение закономерности.

Сначала заметим, что при большом количестве роботов, если они делятся и так и так, их лучше разбивать на пятёрки, допустим, 15 роботов: 3*9>5*5. Это хорошо, если они делятся на 15. А если остаётся остаток? Анализируем.

0: Это 5+5+...+5. Нечего переразбивать, всяко выпуск меньше будет.

1: 5+5+...+5+1. Если оставить последнего без дела, предпоследние выпустят 1*9. А если 5+1 заменить на 3+3, выпустят 2*5.

2: 5+5+...+5+5+2. Чтобы без дела механизмы не стояли, последних 12 предположим разбить по 3. Проверяем. 1*9+1*9=18, 1*9+2*5=19, 4*5=20. Предположение оправдалось.

3: Ясен день, всех по 5, а последних по 3.

4: 5+5+...5+4. 5+4 заменяем на 3+3+3, потому что 1*9+1*5<3*5.

5: Аналогично 0

6: Аналогично 1

... остаток от деления на 15 вычислять смысла нет, достаточно вычислить остаток от деления на 5.

С огромными количествами разобрались. А как с малыми? Да просто написать, что да как. Пишем.

Кол-во	mod 5	Разбиение
0	0	0x5+0x3
1	1	0x5+0x3
2	2	0x5+0x3
3	3	0x5+1x3
4	4	0x5+1x3
5	0	1x5+0x3
6	1	0x5+2x3
7	2	0x5+2x3
8	3	1x5+1x3
9	4	0x5+3x3
10	0	2x5+0x3
11	1	1x5+2x3
12	2	0x5+4x3
13	3	2x5+1x3
14	4	1x5+3x3
15	0	3x5+0x3
16	1	2x5+2x3
17	2	1x5+4x3
18	3	3x5+1x3

Ну и... Что имеем с гуся? Пытаемся вывести выражение для количества.

Анализируем. Приходим к выводу, что, если количество не принадлежит множеству [1, 2, 4, 7], то вычисление групп производится так же, как и в случае с большим количеством роботов. Можно было бы написать

Pascal
1
if k in [1, 2, 4, 7] then ... else ...

, но я заметил ещё и следующее:

Если роботов k<8 и k≠5, то образуются группы только из 3 роботов, и количество этих групп k mod 3.

Теперь попытаемся написать аналитическое выражение для оставшихся количеств, то есть, для k=5 и k≥8.

Сначала, опираясь на остаток от деления на 5, вычисляем число групп по 3. Сначала я написал

Pascal
1
2
3
4
5
6
7
case k mod 5 of
  0: t := 0;
  1: t := 2;
  2: t := 4;
  3: t := 1;
  4: t := 3
end;

Но, приглядевшись к этой длинной конструкции, я понял, что, если вычислить остаток от деления на 5, умножить его на 2 и от этого дела вычислить снова остаток от деления на 5, числа будут те же самые. Действительно:

k mod 5 = 0; 0 * 2 = 0; 0 mod 5 = 0;
k mod 5 = 1; 1 * 2 = 2; 2 mod 5 = 2;
k mod 5 = 2; 2 * 2 = 4; 4 mod 5 = 4;
k mod 5 = 3; 3 * 2 = 6; 6 mod 5 = 1;
k mod 5 = 4; 4 * 2 = 8; 8 mod 5 = 3.

t = k mod 5 * 2 mod 5. Voila!

Ну, как бы я молодец, case громоздкое сократил. Да вот бедулька: Как быть с количеством групп по 5? Ну, как, как... Поделить их всех по 5, а затем вычесть что-то, опираясь на количество групп по 3, либо на остаток.

Сначала хотел так:

Pascal
1
2
3
t := k mod 5 * 2 mod 5;
k := k - t * 3;
p := k mod 5;

Но не понравилась мне последняя строка: там этих железяк ну так очень по 5, что аж зубы ломит. Попробовал отпереться от остатка, но ничего доброго не получилось: вышло длиннее окончательного варианта, хотя и короче, чем вышеприведённое:

Pascal
1
2
t := k mod 5 * 2 mod 5;
p := k mod 5 - k mod 5 div 3;

Но смутило меня масло масляное k mod 5. Попробовал опереться об уже вычисленное t. И заметил, что для данного диапазона чисел k mod 5 div 3 = t div 2. Для ускорения программы заменил деление нацело на 2 арифметическим сдвигом вправо. Результат тот же, скорость выше. Окончательно получилось

Pascal
1
2
t := k mod 5 * 2 mod 5 
p := k div 5 - t asr 1;

Ну ладно, далее цикл по годам, и всё такое... Но как определить, какие роботы от фирмы "Дохлер"? Понятно, по возрасту более 3 лет. Сначала думал сделать, как Ромаха, четыре переменные, и переприсваивать их каждый год по кругу, тем самым стариков отправляя на свалку, но вспомнил про стандартное решение с вычислением индекса массива как модуля от некоего числа. Получается, что элементов массива должно быть 3, под номерами 0, 1 и 2, и при надлежащем обращении к элементам массива только что вылупившиеся чугунины будут автоматически замещать отправленных на утилизацию дохлеров.

Всё. Далее просто пишем программу.

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
var k, n, i, t, p: longint;
    a: array [0..2] of longint;
 
begin
  assign(input, 'input.txt'); reset(input);
  assign(output, 'output.txt'); rewrite(output);
  read(k, n);
  a[0] := k; a[1] := 0; a[2] := 0; //старых k, молодых нет
  for i := 1 to n-1 do //цикл по годам
    begin
      if (k < 8) and (k <> 5) //если так,
        then begin //то
          t := k div 3; //только по 3
          p := 0 //по 5 нет
        end
        else begin //если иначе,
          t := k mod 5 * 2 mod 5; //по 3 в зависимости от остатка деления на 5
          p := k div 5 - t shr 1 //по 5... ну по 5, за вычетом количества групп, которые ушли на формирования групп по 3
        end;
      a[i mod 3] := 5 * t + 9 * p; //пишем юношей, стариков, если они там были, на свалку
      k := a[0] + a[1] + a[2]; //находим новое количество роботов
    end;
  write(k) //ну и... печатаем, сколько их там наклонировалось, если они не вымерли, конечно...
end.

Но меня смутило, что, если механизмов меньше 3, а срок большой, так эта программулина и будет в течение незнамо сколько лет 0 на 0 перемножать и с 0 складывать. Добавил условие k≥3 и n≥4 в угоду скорости выполнения, но проиграв в объёме программы... Не знаю... Зря, может быть... Попробуйте этот вариант, кто их поймёт, эти ацмп, что им надо для повышения оценки... Объём программы, быстродействие... По-моему, всё ж минимальный объём... Так что, может, я ошибся с добавлением условий...

Всего Вам доброго.

Новые блоги и статьи Все статьи Все блоги /
Особенности gif сгенерированных в Си russiannick 21.10.2026 Рассмотрим генерацию gif файлов, которые в Си имеют свои особенности. Gif представляет собой графический формат популярный в интернете. Посмотрим на палитру. Gif файл сгенерированный в си отличается. . .	FPS контроллер с анимированными Y-Bot и 3D-звуком miniaudio (Box3D, Recast, BehaviorTree.CPP, ozz-animation, ImGui, OpenGL и SDL3) 8Observer8 18.10.2026 Содержание блога \| English Version Полное мультиплатформенное руководство по стартовому проекту с FPS-контроллером игрока, анимированными роботами Y-Bot с 4-слойным блендингом, 3D-физикой Box3D,. . .	Локальный http сервер Argus19 17.10.2026 Локальный http сервер На работе, на двух локальных компьютерах круглосуточно работают программы опроса приборов с записью в книги Excel,которые раз в сутки записываются на сервер компании. Т. к. . . .	Копировать Windows на новый диск на UEFI damix 17.10.2026 https:/ / uriesk. wordpress. com/ 2016/ 11/ 01/ move-window-10-to-ssd-on-a-uefi-dualboot-system-with-basic-linux-tools/ TL DR Вставляем диск, а старый подключаем через переходник, грузимся с лайва. . .
ИИ не может найти нужный язык в списке Supersumestria 05.10.2026 Я ему даю вот такое изображение и прошу найти и подчеркнуть немецкий язык. Возвращает он вот это: https:/ / i. **********/ vqBWLe2. png Нужную строчку в 3й колонке просто выдумал. . Это. . .	Новая последняя моя музыка в SUNO zorxor 05.10.2026 Здравствуйте, дорогие мои друзья! С большой радостью я хотел бы представить вам свою новую последнею музыку, которую сгенерировала мне по моей просьбе нейросеть SUNO. С уважением, zorxor. Это. . .	Программный домашний кинотеатр russiannick 27.09.2026 Сподобился на программный домашний кинотеатр. В качестве ЯВУ по традиции выбрал js. В помощники взял Яндекс-Алису. Было создано три зала на разные интересы. исторические и ретро сериал Хичкок. . .	Беседа с ИИ о программистах, недопускающих к созданию и правке кода генеративные ИИ и причины этого zorxor 21.09.2026 Раньше я радовался или получал некоторые эмоции, пусть небольшие, но всё же, от самого процесса написания кода, рекомпиляции и запуска, видя постепенное развитие программы и прочее. А теперь лень. . .

@Akcent2 18 / 18 / 14 Регистрация: 27.11.2011 Сообщений: 51

	Каждый робот живет 3 года после сборки. Сколько роботов будет через N лет? 29.11.2011, 21:55. Показов 25736. Ответов 26 Метки нет (Все метки) Сообщество роботов живет по следующим законам: один раз в год они объединяются а полностью укомплектованные группы по 3 или 5 роботов(причем число групп из 3-х роботов-максимально возможное). За год группа из 3-х роботов собирает 5 новых роботов, а группа из 5 роботов - 9 новых роботов. Каждый робот живет 3 года после сборки. Известно начальное количество роботов(k>7, все они только что собраны). Определить сколько роботов будет через N лет. 0

@Cyborg Drone
	24.07.2014, 15:03
	Не по теме: И я ещё немного побуду на форуме, если что, пишите, пока я на работу не упылил... 0

@CrazzyBeer 3 / 3 / 6 Регистрация: 24.03.2014 Сообщений: 65
	24.07.2014, 15:05
	Я пока другую буду решать. Жду ваших вариантов, если будет желание 0

@CrazzyBeer 3 / 3 / 6 Регистрация: 24.03.2014 Сообщений: 65
	20.08.2014, 18:10
	Огромное спасибо, код рабочий. Осталось только понять. К месту было быть хоть чуть чуть объяснений метода Миниатюры 0