Сложение двух двоичных чисел - разобрать код

var sr, sf, ss: string;
function BinAdd(s1, s2: string): string;
var
  s: string;
  l, i, d, carry: byte;
begin
  {выравнивание строк по длине}
  if length(s1) > length(s2) then
    while length(s2) < length(s1) do
      s2 := '0' + s2
  else
    while length(s1) < length(s2) do
      s1 := '0' + s1;
  l := length(s1);
  s := '';
  carry := 0;
  for i := l downto 1 do
  begin
//вот отсюда 
    d := (ord(s1[i]) - ord('0')) + (ord(s2[i]) - ord('0')) + carry;
    carry := d div 2;
    d := d mod 2;
    s := char(d + ord('0')) + s;
  end;
  if carry <> 0 then
    s := '1' + s;
  BinAdd := s;
//до сих пор
end;
begin
  writeln('введите 1-е двоичное число:');
  readln(sf);
  writeln('введите 2-е двоичное число:');
  readln(ss);
  sr := BinAdd(sf, ss);
  writeln('результат сложения = ', sr);
end.

 d := (ord(s1[i]) - ord('0')) + (ord(s2[i]) - ord('0')) + carry; //код первой цифры минус код символа 0
    // плюс код второй цифры минус код символа 0 + перенос из младшего разряда
    //например s1[i]='1' s2[i]='1' перенос=1 будет 1+1+1=3
    carry := d div 2; //перенос будет 3/2=1
    d := d mod 2;//остаток от деления=1
    s := char(d + ord('0')) + s;//в начало строки пишем символ цифры 1=сhr(1+47)='1'
    //кстати  char это ошибка
  end;
  if carry <> 0 then //кончили складывать и, если в переносе 1
    s := '1' + s; //то в начало строки добавляем символ '1'
  BinAdd := s; //присваиваем значение функции

uses crt;
var s1,s2:string;
    a,b,c:array[byte] of byte;
    base,na,nb,i,j,n,p:byte;
    t,k:integer;
    f:boolean;
begin
clrscr;
repeat
write('Введите основание СС от 2 до 9 base=');
readln(base);
until base in [2..9];
{ввод чисел с проверкой}
repeat
write('Введите число A:');
readln(s1);
i:=1;
f:=true;
while(i<=length(s1))and f do
if not(ord(s1[i])-48 in [0..base-1])then f:=false
else i:=i+1;
if not f then writeln('Это не число в СС ',base,' повторите ввод');
until f;
repeat
write('Введите число B:');
readln(s2);
i:=1;
f:=true;
while(i<=length(s2))and f do
if not(ord(s2[i])-48 in [0..base-1])then f:=false
else i:=i+1;
if not f then writeln('Это не число в СС ',base,' повторите ввод');
until f;
{нормализация}
na:=length(s1);
nb:=length(s2);
for i:=1 to na do
  begin
    val(s1[i],t,k);
    a[i]:=t;
  end;
for i:=1 to nb do
  begin
    val(s2[i],t,k);
    b[i]:=t;
  end;
if na>nb then
  begin
    n:=na;
    for i:=1 to na-nb do
      begin
        nb:=nb+1;
        for j:=nb downto 2 do
        b[j]:=b[j-1];
        b[1]:=0;
      end;
   end
else if nb>na then
   begin
     n:=nb;
     for i:=1 to nb-na do
       begin
         na:=na+1;
         for j:=na downto 2 do
         a[j]:=a[j-1];
         a[1]:=0;
       end;
    end
else if nb=na then n:=na;
p:=0;
for i:=n downto 1 do
  begin
   c[i]:=a[i]+b[i]+p;
   if (c[i]>base-1)and(i>1) then
      begin
       c[i]:=c[i] mod base;
       p:=1;
      end
    else p:=0;
  end;
if c[1]>base-1 then
  begin
    c[1]:=c[1] mod base;
    n:=n+1;
    for j:=n downto 2 do
    c[j]:=c[j-1];
    c[1]:=1;
  end;
writeln('Chislo C:');
for i:=1 to n do
write(c[i]);
readln
end.