Поменять местами первую строку со строкой проходящей через наибольший по модулю элемент побочной диагонали

program _matrix;
 
const
 
 N  = 5;
 
type 
 
 TMatrix   = array [1..N, 1..N] of integer;
 TPosition = record
  i     : byte;
  j     : byte;
  val   : integer;
 end;
 
 
var
 
 Matrix     : TMatrix;
 Max        : TPosition;
 
procedure FillMatrix(var MTR : TMatrix;rnd : boolean;lb,rb:integer);
{процедура заполнения матрицы значениями из (lb,rb)
 rnd=true - случайнo rnd=false - вручную           } 
 var  
  i,j       : byte;
  x         : integer;
 function RandomInt(a,b:integer):integer;
 {возвращает случайное целое из (a;b)}
  var
   x        : integer;
   sign     : 0..1;
  begin
   x:=0;
   if a<=b then 
    begin
     if b<0 then 
      repeat 
       x:=-random(Abs(a))
      until (x>a) and (x<b);
    if b>0 then 
     repeat 
      x:=random(b);
      sign:=random(2);
      if sign>0 then x:=-x;
     until (x>a) and (x<b);
   end;
  RandomInt:=x;   
 end;
begin
 Writeln();
 case rnd of 
    TRUE : begin
            for i:=1 to N do 
            for j:=1 to N do 
            MTR[i,j]:=RandomInt(lb,rb);
           end;
    FALSE: begin
            for i:=1 to N do 
            for j:=1 to N do 
             begin
              repeat
               write('[',i,',',j,',]: ' );
               readln(x);
              until (x>lb) and (x<rb);
              MTR[i,j]:=x;
             end;
           end;
 end;   
 writeln();
end;
 
procedure PrintMatrix(const MTR : TMatrix);
{процедура вывода матрицы на экран      }
 var
  i,j       : integer;
begin
 writeln();
 for i:=1 to N do begin
 for j:=1 to N do write(MTR[i,j]:3,' ');
                  writeln();
                  end;
 writeln();               
end;
 
procedure SwapLines(var MTR : TMatrix; a,b : integer);
{   процедура меняет местами строки матрицы 
              с номерами a,b              }
 var
  i         : integer;
  temp      : array [1..N] of integer;
begin
for i:=1 to N do temp[i] := MTR[a,i];
for i:=1 to N do MTR[a,i]:= MTR[b,i];
for i:=1 to N do MTR[b,i]:= temp[i];
end; 
 
function GetAbsMaxOnSD(const MTR: TMatrix):TPosition;
{ возвращает максимальный по модулю эл-нт побочной диагонали матрицы}
var 
 Max        : TPosition;
 i          : byte;
begin
 Max.i:=1;Max.j:=N;Max.val:=Abs(MTR[1,N]);
 for i:=1 to N do if Max.val<Abs(MTR[i,N+1-i])
                    then begin
                          Max.i:=i;Max.j:=N+1-i;
                          Max.val:=Abs(MTR[i,N+1-i]);
                         end;
 GetAbsMaxOnSd:=Max;
end;
 
BEGIN
 
{ fill & print Matrix }
 randomize;
 FillMatrix(Matrix,true,-100,100); { false если вручную}
 writeln('form. matrix: ');
 PrintMatrix(Matrix);
 
{ process. & output }
 Max:=GetAbsMaxOnSD(Matrix);
 Writeln('abs Max on secondary diagonal: ',max.val);
 SwapLines(Matrix,1,max.i);
 Writeln('modif. matrix: ');
 Printmatrix(Matrix);
END.