Защита от ввода неверного типа данных

program Project1;
 
var
  S : String;
  Num : Longint;
  Code : Integer;
begin
  Writeln('Задайте целое число:');
  repeat
    Readln(S);
    Val(S, Num, Code);
    if Code <> 0 then
      Writeln('Неверный ввод. Должно быть задано целое число. Пвторите.');
  until Code = 0;
  Writeln('Ввод завершён. Введено число: ', Num);
  Writeln('Чтобы выйти нажмите Enter.');
  Readln;
end.

program Project1;
 
var
  S : String;
  Num : Longint;
  Code : Integer;
begin
  Writeln('Задайте целое число:');
  repeat
    {$I-} {Отключаем генерацию ошибок ввода/вывода.}
    Readln(Num);
    {$I+} {Включаем генерацию ошибок ввода/вывода.}
    Code := IOResult; {Читаем код результата выполнения операции.}
    if Code <> 0 then {Проверяем - была ли ошибка.}
      Writeln('Неверный ввод. Должно быть задано целое число. Повторите.');
  until Code = 0;
  Writeln('Ввод завершён. Введено число: ', Num);
  Writeln('Чтобы выйти нажмите Enter.');
  Readln;
end.

program Project1;
 
uses
  Crt;
 
var
  S : String;
  Ch : Char;
  i : Integer;
begin
  Writeln('Задайте строку, в которой 1..8 десятичных цифр:');
  i := 0;
  repeat
    {Читаем очередной символ из стандартного входного файла.}
    Ch := ReadKey;
    {Если символ является цифрой, то добавляем его в строку.}
    if Ch in ['0'..'9'] then begin
      Inc(i);      {Подсчёт количества введённых цифр.}
      S := S + Ch; {Добавляем цифру в конец строки.}
      Write(Ch);   {Показываем цифру на экране.}
    end;
    {Выход из цикла в случае, если введена хотя бы одна цифра и нажат Enter,
    либо, если введено 8 цифр.}
  until ((Ch = #13) and (i >= 1)) or (i = 8);
  Writeln;
  Writeln('Ввод завершён. Введена строка: ', S);
  Writeln('Чтобы выйти нажмите Enter.');
  Readln;
end.

program Project1;
 
uses
  Crt;
 
var
  S : String;
  Ch : Char;
  i, x, y : Integer;
begin
  Writeln('Задайте строку, в которой 1..8 десятичных цифр:');
  i := 0;
  repeat
    {Читаем очередной символ из стандартного входного файла.}
    Ch := ReadKey;
    {Если символ является цифрой, то добавляем его в строку.}
    case Ch of
      {Если введена десятичная цифра.}
      '0'..'9' :
      begin
        Inc(i);      {Подсчёт количества введённых цифр.}
        S := S + Ch; {Добавляем цифру в конец строки.}
        Write(Ch);   {Показываем цифру на экране.}
    end;
    {Если нажата клавиша BackSpace - т. е., дана команда стереть
    символ, расположенный слева от курсора.}
    #8 :
      if i > 0 then begin
        {Получаем координаты позиции, непосредственно слева от курсора.}
        x := WhereX - 1;
        y := WhereY;
        {Переходим к вычисленной позиции.}
        GotoXY(x, y);
        {Устанавливаем цвет текста таким же, как цвет фона.}
        TextColor(0);
        {Распечатываем последний символ строки цветом, совпадающим
        с цветом фона. Тем самым, стираем этот символ на экране.}
        Write(S[i]);
        {Устанавливаем обычный цвет текста - белый.}
        TextColor(7);
 
        Delete(S, i, 1); {Исключаем символ из строки.}
        Dec(i); {Исключаем символ из подсчёта.}
        Write(Ch); {Посылаем в стандартный выходной файл символ Ch = #8 (BackSpace).}
      end;
    end;
    {Выход из цикла в случае, если введена хотябы одна цифра и нажат Enter,
    либо, если введено 8 цифр.}
  until ((Ch = #13) and (i >= 1)) or (i = 8);
  Writeln;
  Writeln('Ввод завершён. Введено: ', S);
  Writeln('Чтобы выйти нажмите Enter.');
  Readln;
end.