Объяснить работу функции

@Aneron · Регистрация: 20.04.2010

Author24 — интернет-сервис помощи студентам

Добрый день.

Решил поизучать на досуге Perl и столкнулся с проблемой.

Есть у меня две функции:

Perl

sub getAvarageTime
{
    if($_[1]=~ m/^\s*execute\s*(.*)/gi)
    {
                #Выполняет что то.
        return 1;       
    }
    else
    {
        return -1;
    }   
}
 
sub getExplain
{   
    if($_[1]=~ m/^\s*execute\s*(.*)/gi)
    {       
        #Выполняет что то.
        return "ok";            
    }
    else
    {
        return "no";
    }   
}

И собственно вызов их в коде.

Perl

sub main
{
        my $query; #некая строка.
        my $dbh2;
 
        getAvarageTime($dbh2,$query);
    getExplain($dbh2,$query);
}

Все лишнее выкинул, да бы не было слишком много букв.

Собственно проблема: только в одной функции выражение $_[1]=~ m/^\s*execute\s*(.*)/gi возвращает true, во второй false.
Почему?

volodin661 · 18.03.2014, 05:56

Собственно проблема: только в одной функции выражение $_[1]=~ m/^\s*execute\s*(.*)/gi возвращает true, во второй false.
Почему?

Вопрос получился шикарный,
если рассматривать этот пример через призму
"Влияние стиля прграммирования на возникновение странных ошибок"

я упростил стилистически вышеприведённый код, чтобы было пояснее.

Perl

#!/usr/bin/perl -w
use strict;
 
sub eee {
        my $query = shift;
        return ( $query =~ m/execute\s*(.*)/ig )
                ? "EEE-ok ($1) \n"
                : "EEE-no \n";
}
 
sub fff {
        my $query = shift;
        return ( $query =~ m/execute\s*(.*)/ig )
                ? "FFF-ok ($1) \n"
                : "FFF-no \n";
}
 
my $query = "execute zhoppa s ruchkoj";
 
print "eee call result = ", eee($query);
print "fff call result = ", fff($query);

в таком виде, он отработает корректно:

Кликните здесь для просмотра всего текста

eee call result = EEE-ok(zhoppa s ruchkoj)
fff call result = FFF-ok(zhoppa s ruchkoj)

то есть, когда я стилистически исправлял,
я механически заменил конструкцию номерных аргументов списка @_,
на рекомендованную в смысле правильного стиля my $arg1 = shift;

вернём авторский вариант:

Perl

#!/usr/bin/perl -w
use strict;
 
sub eee {
     
        return ( $_[0] =~ m/execute\s*(.*)/ig )
                ? "EEE-ok ($1) \n"
                : "EEE-no \n";
}
 
sub fff {
       
        return ( $_[0] =~ m/execute\s*(.*)/ig )
                ? "FFF-ok ($1) \n"
                : "FFF-no \n";
}
 
my $query = "execute zhoppa s ruchkoj";
 
print "eee call result = ", eee($query);
print "fff call result = ", fff($query);

и тут же получаем:

Кликните здесь для просмотра всего текста

eee call result = EEE-ok(zhoppa s ruchkoj)
fff call result = FFF-no

Теперь убираем модификатор /g из регулярного выражения m/^\s*execute\s*(.*)/gi ,
( он всё равно не нужен, потому что жадный поиск схавает по / (.*) / всё до конца строки за один присест )

и опять всё становится нормально:

Кликните здесь для просмотра всего текста

eee call result = EEE-ok(zhoppa s ruchkoj)
fff call result = FFF-ok(zhoppa s ruchkoj)

Интрига достигает апогея и в этот волнующий момент наш простой и скромный программист Перл
вспоминает, что выражение $_[n] - это простой alias на собственно переданный аргумент
( или по С-ишному ссылка -> изменив $_[n], мы изменим и сам аргумент ),
а вот выражение $arg1 = shift честно копирует аргумент в $arg1;

одновременно с этим наш скромняга-герой вспоминает, что в скалярном контексте поиск с модификаторм /g
последовательно возвращает каждый следующий найденный шаблон, двигая указатель, который можно, например,
извлечь с помощью функции pos( x ), а поскольку $_[0] в функциях eee() и fff() указывает на одно и то же место и собственно рег. выражение одно и то же, я намекаю на то, что оптимизатор применил шаблон согласно модификатору /g
к одному и тому же выражению 2раза: в первый раз вернулась жопа с ручкой, а второй раз не вернулось ничего, потому что всё уже было съедено и механизм рег. выражений закончил работу.

можно трактовать это как ошибку реализации или же как фичу, но получается, что Д.Конвэй прав -
если писать стилистически красиво, то на такие фичи никогда и не нарвёшься.

Добавлено через 13 минут
а оптимизатор я обвиняю потому,

что если вызывать вот так

Perl

$query = "execute zhoppa s ruchkoj";
print "eee call result = ", eee($uery);
 
$query = "execute zhoppa s ruchkoj";
print "fff call result = ", fff($query);

то тоже будет всё нормально.

@Aneron · 18.03.2014, 09:47 **[ТС]**

Сообщение от volodin661

модификатор /g

Копипаст =) Не думал что он так сказывается.

Сообщение от volodin661

выражение $_[n] - это простой alias на собственно переданный аргумент

Да. Это я понял. Но применение регулярки к строке разве меняет ее?

Сообщение от volodin661

оптимизатор применил шаблон согласно модификатору /g
к одному и тому же выражению 2раза

Но контекст то функций разный. По правилам хорошего тона( по крайней мере С-шного) он должен был применить его еще раз, независимо от предыдущих вызовов.

Просто на С, сие работало бы без проблем)
Спасибо за развернутый ответ.

volodin661 · 18.03.2014, 11:25

Вот так нагляднее:

Perl

#!/usr/bin/perl -w
use strict;
 
sub first {
    return ( $_[0] =~ m/(\w+)/ig ) 
        ? "first-ok($1)\n"
        : "first-no\n";
}
 
 
sub another {
    return ( $_[0]=~ m/(\w+)/ig )
        ? "another-ok($1)\n"
        : "another-no\n";
}
 
sub yet_another {
    return ( $_[0]=~ m/(\w+)/ig )
        ? "yet_another-ok($1)\n"
        : "yet_another-no\n";
}
 
my $query = "aaaa bbbb cccc dddd";
print "first call result = ", first($query);
 
print "another call result = ", another($query);
 
print "yet_another call result = ", yet_another($query);

Результат:

Кликните здесь для просмотра всего текста

first call result = first-ok(aaaa)
another call result = another-ok(bbbb)
yet_another call result = yet_another-ok(cccc)

@Aneron 166 / 164 / 27 Регистрация: 20.04.2010 Сообщений: 607
	18.03.2014, 09:47 [ТС]	3
	Сообщение от volodin661 модификатор /g Копипаст =) Не думал что он так сказывается. Сообщение от volodin661 выражение $_[n] - это простой alias на собственно переданный аргумент Да. Это я понял. Но применение регулярки к строке разве меняет ее? Сообщение от volodin661 оптимизатор применил шаблон согласно модификатору /g к одному и тому же выражению 2раза Но контекст то функций разный. По правилам хорошего тона( по крайней мере С-шного) он должен был применить его еще раз, независимо от предыдущих вызовов. Просто на С, сие работало бы без проблем) Спасибо за развернутый ответ. 0

	18.03.2014, 11:25