Чтение построчно stdin, преобразование строки и запись в stdout

#!perl
 
use strict;
use warnings;
use Getopt::Long;
 
my $in = ''; # по умолчанию
my $out = ''; # по умолчанию
# получаем значения параметров, причём параметры - строки
GetOptions('f=s' => \$in, 'o=s' => \$out);
# если переменная $in не пустая строка - переопределяем STDIN
if ($in ne '') {
    open(STDIN,"<",$in) || die("Error open $in as STDIN\n");
    }
# если переменная $out не пустая строка - переопределяем STDOUT
if ($out ne '') {
    open(STDOUT,">",$out) || die("Error open $out as STDOUT\n");
    }
# обработка данных. в данном случае - добавление + в начало строки
while (my $x = <STDIN>) {
    print STDOUT "+$x";
    }
# закрываем дескрипторы
close(STDIN);
close(STDOUT);

#! /usr/bin/perl -w
use Getopt::Long;
use strict;
 
my $usage = <<END;
 
DESCRIPTION: transfer text from input file to upper case
 
USAGE: $0 [ <option> <file> ] [ <option> <file> ]
    
    OPTIONS:
                --input | -i | -f
                --output | -o
                --help | ?
 
    If both options are omitted, then program reads from STDIN and prints to STDOUT
 
EXAMPLE: $0 --input a.txt --output b.txt
                or
         $0 -f a.txt -o b.txt
 
         $0 -?
END
 
GetOptions(
 
    "input|f|i=s"
        => sub { open STDIN, "<$_[1]" or die $! }, 
    
    "output|o=s"
        => sub { open STDOUT, ">$_[1]" or die $! },
    
    "help|?"
        => sub { print $usage; exit },
 
);
 
print uc while <>;

#! /usr/bin/perl -w
use Getopt::Long;
use strict;
 
GetOptions(
 
    "input|f|i=s"
            => sub { open STDIN, "<$_[1]" or die $! },     
    "output|o=s"
            => sub { open STDOUT, ">$_[1]" or die $! },
    
    "help|?"=> sub { print <<END; exit }
 
ОПИСАНИЕ: преобразует текст входного файла к верхнему регистру 
 
ПРИМЕНЕНИЕ: $0 [ <опция> <файл> ] [ <опция> <файл> ]
    
        ОПЦИИ:
                --input | -i | -f
                --output | -o
                --help | ?
если имена входного и/или выходного файлов опуЩены программа
использует стандартный ввод и/или  вывод
 
ПРИМЕР:  $0 --input a.txt --output b.txt
                or
         $0 -f a.txt -o b.txt
 
         $0 -?
END
        
) and do { print uc while <> }