Удаление ненужных строк

declare @someTable table
(
    name nvarchar(50),
    surname nvarchar(50),
    start time(0),
    endd time(0)
)
 
declare @resultTable table
(
    name nvarchar(50),
    surname nvarchar(50),
    start time(0),
    endd time(0)
)
 
insert into @someTable
values
('Ivan', 'Ivanov', '12:00', '14:00'),
('Ivan', 'Ivanov', '14:00', '15:00'),
('Ivan', 'Ivanov', '16:00', '20:00'),
('Ivan', 'Ivanov', '20:00', '21:00'),
('Ivan', 'Ivanov', '22:00', '23:00')
 
--Собственно решение
declare @cursor cursor
set @cursor = cursor scroll for select * from @someTable
 
declare @name nvarchar(50)
declare @surname nvarchar(50)
declare @start time(0)
declare @end time(0)
 
open @cursor
fetch next from @cursor into @name, @surname, @start, @end
 
while @@fetch_status = 0
begin
    if not exists(select name from @resultTable where name = @name and surname = @surname and endd = @start)
    insert into @resultTable values (@name, @surname, @start, @end)
    else 
    update @resultTable
    set endd = @end
    where name = @name and surname = @surname and endd = @start
    fetch next from @cursor into @name, @surname, @start, @end
end
 
close @cursor
 
select * from @resultTable

declare @someTable table
(
    id int identity primary key,
    name nvarchar(50),
    surname nvarchar(50),
    start time(0),
    finish time(0),
    unique (name, surname, id)
);
 
insert into @someTable
values
('Ivan', 'Ivanov', '12:00', '14:00'),
('Ivan', 'Ivanov', '14:00', '15:00'),
('Ivan', 'Ivanov', '16:00', '20:00'),
('Ivan', 'Ivanov', '20:00', '21:00'),
('Ivan', 'Ivanov', '22:00', '23:00'),
('Пуся', 'Вапкин', '10:00', '13:00'),
('Пуся', 'Вапкин', '13:00', '19:00');
 
with t1 as
(
 select
  name, surname, start, row_number() over (partition by name, surname order by start) as rn
 from
  @someTable a
 where
  not exists(select 1 from @someTable where name = a.name and surname = a.surname and finish = a.start)
),
t2 as
(
 select
  name, surname, finish, row_number() over (partition by name, surname order by finish) as rn
 from
  @someTable a
 where
  not exists(select 1 from @someTable where name = a.name and surname = a.surname and start = a.finish)
)
select
 t1.name, t1.surname, t1.start, t2.finish
from
 t1 join
 t2 on t2.name = t1.name and t2.surname = t1.surname and t2.rn = t1.rn;