Можно как-то переделать код из Turbo Pascal чтобы он работал в pascal abc.net?

uses Graph, Crt;
var
  grDriver: integer;
  grMode: integer;
  ErrCode: integer;
  x,y,y0,a,b: integer;
  procedure more(a,b:integer);
begin
   moveto(0,y0);
   setcolor(blue);
     for a:=0 to 680 do
       begin
         b:=y0-round(sin(a*pi/180)*30);
         lineto(a,b);
 end;
end;
 begin
  grDriver := Detect;
  InitGraph(grDriver, grMode, '..\BGI');
  ErrCode := GraphResult;
  y0 := 250;
  if ErrCode = grOk then
  begin
    x:=600;
    while x>=0 do
     begin
      cleardevice;
      more(a,b);
      setcolor(white);
      y:=y0-40-round(sin(x*pi/180)*30);
      MoveTo(x - 40, y + 20);
      LineTo(x - 20, y + 40);
      LineTo(x + 20, y + 40);
      LineTo(x + 40, y + 20);
      LineTo(x - 40, y + 20);
      MoveTo(x + 15, y + 20);
      LineTo(x + 15, y - 40);
      LineTo(x - 20, y + 20);
      LineTo(x + 15, y + 20);
      delay(100); 
      x:=x-2;
    end;
  end
  else Writeln('Graphics error: ', GraphErrorMsg(ErrCode));
 Settextstyle(0,0,3);
 cleardevice;
 setcolor(red);
 OuttextXY(200,240,'Rejs zavershen!');
 readln;
 CloseGraph;
end.

uses
  GraphABC;
 
var
  x, y, y0, a, b: integer;
 
procedure more(a, b: integer);
begin
  moveto(0, y0);
  setpencolor(clblue);
  for a := 0 to 680 do
  begin
    b := y0 - round(sin(a * pi / 180) * 30);
    lineto(a, b);
  end;
end;
 
begin
  clearWindow(clBlack);
  LockDrawing;
  y0 := 250;
  x := 600;
  while x >= 0 do
  begin
    more(a, b);
    setpencolor(clwhite);
    y := y0 - 40 - round(sin(x * pi / 180) * 30);
    MoveTo(x - 40, y + 20);
    LineTo(x - 20, y + 40);
    LineTo(x + 20, y + 40);
    LineTo(x + 40, y + 20);
    LineTo(x - 40, y + 20);
    MoveTo(x + 15, y + 20);
    LineTo(x + 15, y - 40);
    LineTo(x - 20, y + 20);
    LineTo(x + 15, y + 20);
    x := x - 2;
    Redraw;
    Sleep(1);
    
    ClearWindow(clBlack);
  end;
  
  SetFontSize(14);
  setpencolor(clred);
  textOut(200, 240, 'Rejs zavershen!');
  readln;
end.