Построение графиков функций в декартовой системе координат.

uses graph;
const
x1=-10;{начало и конец графика в реальных значениях}
x2=10;
procedure Okno(x,y:integer;var d:integer;var m:real);
var i:integer;
    s:string;
begin
d:=y-100;{ширина и высота окон}
{коэффициенты по осям для перевода реальных координат в экранные}
m:=2*d/(x2-x1);{длина в пикселах по оси Х/реальная длина}
setcolor(15);
rectangle(x-d-5,y-d-5,x+d+8,y+d+10);
setfillstyle(1,15);
floodfill(x,y,15);
setcolor(8);{цвет линий осей}
line(x-d,y,x+d,y); {ось Х}
line(x,y-d,x,y+d); {ось У}
{центр}
outtextXY(x+5,y+10,'0');
{подписи концов осей}
outtextXY(x+d-10,y-10,'X');
outtextXY(x+5,y-d+10, 'Y');
for i:=1 to 2 do
 begin
  line(x-3,y-round(5*i*m),x+3,y-round(5*i*m));{засечки на оси У}
  line(x-3,y+round(5*i*m),x+3,y+round(5*i*m));
  line(x+round(5*i*m),y-3,x+round(5*i*m),y+3); {засечки на оси Х}
  line(x-round(5*i*m),y-3,x-round(5*i*m),y+3);
  str(5*i,s);
  {подпись оси У}
  outtextXY(x-15,y-round(5*i*m),s);{соответственно засечкам}
  outtextXY(x-25,y+round(5*i*m),'-'+s);
  {подпись оси Х}
  outtextXY(x+round(5*i*m)-5,y+10,s);
  outtextXY(x-round(5*i*m),y+10,'-'+s);
  end;
end;
var m,xt,dx,y1,y2:real;
    xc1,yc1,xc2,yc2,d1,grD,grM,px1,px2,py:integer;
begin
grD:=detect;
initgraph(grD,grM,'');
setbkcolor(9);
setcolor(15);
outtextXY(30,30,'Grafik functii Y1=sqrt(x^2+2)*sinx');
outtextXY(getmaxX div 2+30,30,'Grafik functii Y2=s(x+1)*sinx');
xc1:=getmaxX div 4;{начало координат в центре 1 окна}
yc1:=getmaxY div 2;
xc2:=3*(getmaxX div 4);{начало координат в центре 2 окна}
yc2:=getmaxY div 2;
Okno(xc1,yc1,d1,m);{1 окно}
Okno(xc2,yc2,d1,m);{2 окно}
{графики}
dx:=0.001;
xt:=x1;
while xt<=x2 do
   begin
     px1:=xc1+round(xt*m); {изменение по оси Х}
     px2:=xc2+round(xt*m);
     y1:=sqrt(xt*xt+2)*sin(xt); {1 график в реальных координатах}
     py:=yc1-round(y1*m);{в экранных}
     putpixel(px1,py,9);
     y2:=(xt+1)*sin(xt); {2 график в реальных координатах}
     py:=yc2-round(y2*m);{в экранных}
     putpixel(px2,py,5);
     xt:=xt+dx; {наращиваем х}
   end;
readln
end.