Нужно перевести код с Pascal ABC на Turbo Pascal - рисование работающей мельницы

uses graphABC,crt;
type point=record
           x,y:integer;
           end;
//отрисовка лопастей в виде замкнутого полигона
//параметры: центральная точка, радиус, цвет, текущий угол поворота
procedure Lop(xc,yc,r,c:integer;u0:real);
var p:array[1..13] of point;
    i:integer;
    u,du:real;
begin
u:=pi/4;du:=u/4;//первая лопасть по 45 гр., ввер и вниз на 45/4 гр.
for i:=1 to 4 do
 begin
  p[3*i-2].x:=xc; p[3*i-2].y:=yc;//первые точки в центре
  p[3*i-1].x:=xc+round(r*cos(u0+u-du));
  p[3*i-1].y:=yc-round(r*sin(u0+u-du));
  p[3*i].x:=xc+round(r*cos(u0+u+du));
  p[3*i].y:=yc-round(r*sin(u0+u+du));
  u:=u+pi/2;//лопасти через 90 градусов
 end;
p[13].x:=p[1].x; p[13].y:=p[1].y; //замкнем
setpencolor(c);
polygon(p,13); //рисуем заданным цветом
end;
//помещение мельницы, все размеры от радиуса
procedure Meln(xc,yc,r,c:integer);
var p:array[1..5] of point;
    i:integer;
begin
p[1].x:=xc-r div 3;p[1].y:=yc-r div 10;
p[2].x:=xc+r div 3;p[2].y:=yc-r div 10;
p[3].x:=xc+2*r div 2;p[3].y:=yc+2*r;
p[4].x:=xc-2*r div 2;p[4].y:=yc+2*r;
p[5].x:=p[1].x;p[5].y:=p[1].y;
setpencolor(c);
polygon(p,5);
end;
var x,y,r:integer;
    u:real;
begin
r:=150; //зададим радиус
SetWindowSize(3*r,7*r div 2); //задалим подходящие размеры окна
x:=windowwidth div 2; y:=r+10;//центральная точка лопастей
hidecursor;//спрячем курсор
u:=0; //в цикле перерисовываем с поворотом лопастей
repeat
Meln(x,y,r,clRed);
Lop(x,y,r,clBlack,u);
delay(100);
Meln(x,y,r,clWhite);
Lop(x,y,r,clWhite,u);
u:=u+pi/16;
until keypressed; //пока не нажата клавиша
end.

uses graph,crt;
type point=record
           x,y:integer;
           end;
procedure Lop(xc,yc,r,c:integer;u0:real);
var p:array[1..13] of point;
    i:integer;
    u,du:real;
begin
u:=pi/4;du:=u/4;
for i:=1 to 4 do
 begin
  p[3*i-2].x:=xc; p[3*i-2].y:=yc;
  p[3*i-1].x:=xc+round(r*cos(u0+u-du));
  p[3*i-1].y:=yc-round(r*sin(u0+u-du));
  p[3*i].x:=xc+round(r*cos(u0+u+du));
  p[3*i].y:=yc-round(r*sin(u0+u+du));
  u:=u+pi/2;
 end;
p[13]:=p[1];
setcolor(c);
drawpoly(13,p);
{почему-то полигон не рисует одну линию,
в АВС все рисует, поэтому добавим}
line(p[4].x,p[4].y,p[5].x,p[5].y);
end;
 
procedure Meln(xc,yc,r,c:integer);
var p:array[1..5] of point;
    i:integer;
begin
p[1].x:=xc-r div 3;p[1].y:=yc-r div 10;
p[2].x:=xc+r div 3;p[2].y:=yc-r div 10;
p[3].x:=xc+2*r div 2;p[3].y:=yc+2*r;
p[4].x:=xc-2*r div 2;p[4].y:=yc+2*r;
p[5].x:=p[1].x;p[5].y:=p[1].y;
setcolor(c);
drawpoly(5,p);
end;
var x,y,r:integer;
    u:real;
begin
initgraph(x,y,'');
r:=150;
x:=getmaxX div 2;
y:=r+10;
u:=0;
repeat
Meln(x,y,r,12);
Lop(x,y,r,15,u);
delay(100);
Meln(x,y,r,0);
Lop(x,y,r,0,u);
u:=u+pi/16;
until keypressed;
end.