Сортировка Шелла

uses Crt;
const
{ Размер массива }
nmax = 16000;
type
{ Тип массива }
mas = array [1..nmax] of integer;
var size:integer;
{Сортировка Шелла }
procedure ShellSort( var A : mas );
const steps = 12;
var i, j, l, k, p, n, x : Integer;
    s : array [1..steps] of Integer;
begin
k := 1;
{ Формируем последовательность чисел -
  шаги, с которыми выбираем сортируемые подмассивы }
for i := steps downto 1 do
 begin
  s[i] := k;
  k := k * 2 + 1;
 end;
{ Сортировки подмассивов вплоть до шага 1 -
  обычной сортировки пузырьком }
for k := 1 to steps do
 begin
  l := s[k];
 { Для каждого шага l нужно отсортировать l подмассивов }
  for p := 1 to l do
   begin
    i := size - l;
    n := 1;
 { Сортировка подмассива пузырьком с остановкой }
 { Подмассив - это (A[p], A[p+l], A[p+2*l], ...) }
    while n > 0 do
     begin
      n := 0;
      j := p;
      while j <= i do
       begin
        if A[j] > A[j + l] then
         begin
          x := A[j];
          A[j] := A[j + l];
          A[j + l] := x;
          n := 1;
         end;
        j := j + l;
       end;
      i := i - l;
     end;
    end;
   end;
  end;
var A : mas;
    i, j : Integer;
begin
clrscr;
randomize;
write('Введите размер массива до ',nmax,' size=');
readln(size);
writeln('Исходный массив:');
for i:=1 to size do
 begin
  a[i]:=random(100);
  write(a[i]:4);
 end;
writeln;
ShellSort(a);
writeln('Отсортированный массив:');
for i:=1 to size do
write(a[i]:4);
readln
end.