Combo Box/ dropdown list

Dim a_s, tmp_s As Object
 
Private Sub UserForm_Initialize()
Set a_s = ActiveSheet
        'Создаем новый лист в конце книги,
Set tmp_s = Sheets.Add(, Sheets(Sheets.Count))
a_s.Activate
With tmp_s
        'копируем в него первые 3 столбца из текущего листа,
    a_s.Range("A:C").Copy .Range("A1")
        'сортируем,
    .Range("a1").Sort key1:=.Range("a1"), order1:=xlAscending, header:=xlYes
        'копируем заголовок для списка условий фильтра
    .Range("a1:c1").Copy .Range("e1")
        'вставляем пустую строку, чтобы заголовок не попал в поле-список
    .Rows(2).Insert Shift:=xlDown
        'Инициализируем поле-список
    ListBox1.ColumnCount = 3
    ListBox1.RowSource = .Name & "!" & .Range("a3").CurrentRegion.Address
End With
End Sub
 
Private Sub UserForm_Terminate()
Application.DisplayAlerts = False
tmp_s.Delete
Application.DisplayAlerts = True
End Sub
 
Private Sub TextBox1_Change()
        'При изменении содержимого текстбокса
With tmp_s
        'Очищаем результаты работы фильтра
    .Columns("i:k").ClearContents
        'Назначаем условие фильтра по 1-му столбцу.
        'В таком виде поиск будет по вхождению текста.
        'Чтобы искать по началу, надо удалить первые "*" &
    .Range("e2") = "*" & TextBox1.Text & "*"
        'Применяем фильтр
    .Range("A:C").AdvancedFilter Action:=xlFilterCopy, CriteriaRange:=.Range( _
        "E1:G2"), CopyToRange:=.Range("I1"), Unique:=False
        'вставляем пустые ячейки, чтобы заголовок не попал в поле-список
    .Range("I2:K2").Insert Shift:=xlDown
        'Назначаем поле-списку новое содержимое
    ListBox1.RowSource = .Name & "!" & .Range("i3").CurrentRegion.Address
End With
End Sub