Найти количество четных чисел, содержащихся в диапазоне

Sub m_1()
'С помощью инструмента Dim создаём на пластинке оперативной памяти
'поименованную область (переменную) oCell.
'Range означает, что в переменной будет находиться одна
'или несколько ячеек Excel.
Dim oCell As Range
'For Each ... In ... Next - называется циклом и используется для обработки
'всех элементов одной коллекции. Под коллекцией в VBA понимается
'набор одинаковых объектов. В нашем случае элементом коллекции
'является одна ячейка, а коллекция - это все выделенные ячейки.
For Each oCell In Selection.Cells
    'Rnd - инструмент VBA для генерации случайных чисел.
    'Для генерирования случайных чисел нужно использовать следующую формулу:
    '(max - min + 1) * Rnd + min.
    'Int используется, чтобы рандомные числа были целые, а не дробные.
    oCell.Value = Int((100 - (-100) + 1) * Rnd + (-100))
Next oCell
End Sub

'Диапазон - это переменная, содержащая выделенные ячейки.
'ТипРезультата - это переменная, в которую будет помещаться число 1 или 2.
'Integer означает, что в переменной могут быть только целые числа (есть ещё дробные).
Function ЧётныеНечётные(Диапазон As Range, ТипРезультата As Integer)
Dim oCell As Range
Dim Количество As Integer
'If ... Then ... ElseIf ... End If - используется для выбора действия.
'Если в переменную ТипРезультата поместят число 1, то
'функция будет определять количество чётных чисел.
If ТипРезультата = 1 Then
    For Each oCell In Диапазон
        'Далее для определения чётности и нечётности будет использован
        'инструмент VBA - Mod. Mod используется для определения остатка от деления.
        'Можно мысленно заменить в коде Mod на знак деления "/", только результатом 
        'будет остаток от деления. Делить будем на 2; если число делится на 2 
        'без остатка, то оно чётное, если с остатком - то нечётное.
        If oCell.Value Mod 2 = 0 Then
            'Если число делитя на 2 без остатка, то сделаем запись 
             'в переменной Количество.
            Количество = Количество + 1
        End If
    Next oCell
    'ЧётныеНечётные - это название функции, то есть в функцию помещаем значение
    'из переменной Количество.
    ЧётныеНечётные = Количество
'Если в переменную ТипРезультата поместят число 2, то
'функция будет определять количество нечётных чисел.
ElseIf ТипРезультата = 2 Then
    For Each oCell In Диапазон
        If oCell.Value Mod 2 <> 0 Then
            'Если число делится на 2 с остатком, то сделаем запись 
            'в переменной Количество.
            Количество = Количество + 1
        End If
    Next oCell
    ЧётныеНечётные = Количество
End If
End Function

Sub Кнопка1_Щелкнуть()
Dim R As Range
Dim ПРИЗНАК As Integer
Set R = Selection
ПРИЗНАК = InputBox("Введите признак результата", "Запрос признака", 1)
MsgBox ЧётныеНечётные(R, ПРИЗНАК)
End Sub