VBA в Access

Sub P1()
Dim НаборЗаписей As New ADODB.Recordset
Dim Эксель As New Excel.Application
Dim Книга As Excel.Workbook, Лист As Excel.Worksheet
Dim Флаг As Boolean
Dim LastRow As Long
Dim i As Long
Dim Файл As Variant
'Перед запуском кода, надо чтобы таблица была закрыта.
'Способ закрытия (с сохранение или без) укажите сами (например,acSaveNo).
'Способы закрытия выскакивают, когда нажимаешь запятую.
DoCmd.Close acTable, "Таблица1", acSaveNo
'Помещаем во что-то там таблицу из Access и именно где-то там и будем работать
'с этой таблицей. По окончании работы что-то там поместим в таблицу Access.
НаборЗаписей.Open Source:="Таблица1", ActiveConnection:=CurrentProject.Connection, _
    CursorType:=adOpenKeyset, LockType:=adLockOptimistic
'Выбор файлов Excel для импорта в Access.
With Application.FileDialog(msoFileDialogFilePicker)
    .AllowMultiSelect = True
    .ButtonName = "OK"
    .Filters.Add Description:="Microsoft Excel", Extensions:="*.xls;*.xlsx"
    .Title = "Выберите файлы Excel для импорта в Access"
    If .Show = 0 Then
        Exit Sub
    End If
    'Здесь обрабатываются все выбранные файлы.
    For Each Файл In .SelectedItems
        Set Книга = Эксель.Workbooks.Open(FileName:=Файл)
        For Each Лист In Книга.Worksheets
            If Лист.Name = "База" Then
                Set Лист = Лист
                Флаг = True
                Exit For
            End If
        Next Лист
        If Флаг = False Then
            For Each Лист In Книга.Worksheets
                If Лист.Name = "Лист1" Then
                    Set Лист = Лист
                    Флаг = True
                    Exit For
                End If
            Next Лист
        End If
        If Флаг = False Then
            Set Лист = Книга.Worksheets(1)
        End If
        LastRow = Лист.Cells(Лист.Rows.Count, 2).End(xlUp).Row
        For i = 1 To LastRow
            With НаборЗаписей
                .AddNew
                .Fields(0).Value = Лист.Cells(i, 2)
                .Fields(1).Value = Книга.Name
                .Update
            End With
        Next i
        Книга.Close SaveChanges:=False
        Флаг = False
    Next Файл
End With
Эксель.Quit
НаборЗаписей.Close
Set НаборЗаписей = Nothing
Set Эксель = Nothing
Set Книга = Nothing
Set Лист = Nothing
MsgBox "Готово", vbInformation
End Sub