Заполнить шаблон формы в Excel из таблицы и сохранить в файл Excel

@ZorKon71 · Регистрация: 12.07.2017

Author24 — интернет-сервис помощи студентам

Доброго времени суток.

Есть книга Excel. В ней 4 листа.
На первом листе таблица с данными, которыми должны заполняться формы. Строк много, около 200.
На остальных листах шаблоны форм. Они немного разные. В принципе, во всех формах ячейки заполняются одни и те же.

Есть тонкость, нужно для каждой строки в таблице заполнять не все формы. А только те, которые указаны в отдельной колонке. Бывает, что нужно заполнить несколько форм с данными из одной строки.
Для простоты, я могу просто сделать разные строки в таблицы.

Хорошо бы при сохранении файла, номер формы и значение из одного столбца участвовало в имени файла.

Помогите пожалуйста. Копипастить в наше время, мне кажется...
Спасибо.

Добавлено через 15 минут
Пример шаблона: тут

Код/№	Организация	Задание	Кол-во	Должность	Ф.И.О.	Формы
-1-	-2-	-3-	-4-	-5-	-6-	-7-
QWE	ООО "Класс"	Купить авто	5	Генеральный директор	Карачун О.Д.	Форма 1
ASD	ЗАО "АУ"	Уборка двора	10	Директор	Пустышка И.О.	Форма 2
ZXC	ИП "Заяц И.И."	Оформить документы	3		Заяц И.И.	Форма 1, Фориа 2

Добавлено через 2 минуты
Должно получиться 4 файла:
Форма 1_QWE.xls
Форма 2_ASD.xls
Форма 1_ZXC.xls
Фориа 2_ZXC.xls

@KoGG · 04.08.2022, 17:32

Visual Basic

Sub Заполнить_и_сохранить_формы()
    Dim i&, j&, lastRow&, A, F, FormaName, Wb1 As Workbook, MyPath$, MyFileName$
    MyPath = ActiveWorkbook.Path & "\"
    Set Wb1 = ActiveWorkbook
    Application.DisplayAlerts = False
    With ActiveSheet
        lastRow = .Cells(.Rows.Count, 1).End(xlUp).Row
        A = .Range("A1:G" & lastRow).Value
    End With
    For i = 3 To lastRow
        For Each FormaName In Split(A(i, 7), ",")
            FormaName = Trim(FormaName)
            With Wb1.Sheets(FormaName)
                .[A1] = A(i, 2)
                .[A8] = A(i, 3)
                .[D8] = A(i, 4)
                .[D14] = A(i, 5)
                .[E16] = A(i, 6)
                .Copy
            End With
            MyFileName = MyPath & FormaName & "_" & A(i, 1) & ".xls"
            ActiveWorkbook.SaveAs Filename:=MyFileName, FileFormat:=xlExcel8
            For j = 1 To 200: DoEvents: Next
            ActiveWorkbook.Close 0
        Next
    Next
    Application.DisplayAlerts = True
End Sub

Если написано Форма 1, Фориа 2
, то на 2-ой форме будет ошибка.

@ZorKon71 · 04.08.2022, 17:37 **[ТС]**

Сообщение от KoGG

Если написано Форма 1, Фориа 2
, то на 2-ой форме будет ошибка.

Хорошо, сделаю разные строки.
Спасибо!

@KoGG · 04.08.2022, 17:51

Строка 1, но формы Фориа не существует.
Для "Форма 1, Форма 2" ошибки не будет.

@ZorKon71 · 09.08.2022, 09:05 **[ТС]**

Спасибо огромное!
Оказалось будет более 300 файлов. Не так просто напечатать...
Но я нашёл и для этого макрос:
Макрос для печати файлов xls из конкретной папки

Спасибо всем, спасли от рутины!

@ZorKon71 0 / 0 / 0 Регистрация: 12.07.2017 Сообщений: 123
	04.08.2022, 17:37 [ТС]	3
	Сообщение от KoGG Если написано Форма 1, Фориа 2 , то на 2-ой форме будет ошибка. Хорошо, сделаю разные строки. Спасибо! 0

@KoGG 5606 / 1592 / 412 Регистрация: 23.12.2010 Сообщений: 2,382 Записей в блоге: 1
	04.08.2022, 17:51	4
	Строка 1, но формы Фориа не существует. Для "Форма 1, Форма 2" ошибки не будет. 1

@ZorKon71 0 / 0 / 0 Регистрация: 12.07.2017 Сообщений: 123
	09.08.2022, 09:05 [ТС]	5
	Спасибо огромное! Оказалось будет более 300 файлов. Не так просто напечатать... Но я нашёл и для этого макрос: Макрос для печати файлов xls из конкретной папки Спасибо всем, спасли от рутины! 0

Заполнить шаблон формы в Excel из таблицы и сохранить в файл Excel

Решение