Макрос открывает файл с форматом дат английский (США)

Public Sub Import_Test_02CSV()
Dim sglTimerStart As Single, sglTimerEnd! '(опционально)
Dim sSrcFilePath$, sNewCSVFilePath$, ttt As Single
Dim objSheet As Worksheet, objQTable As QueryTable
    
    sglTimerStart = Timer 'Timer начала
 
'---------------------------------------------------------------------------------------------------
' Исходный файл
    'sSrcFilePath = "d:\Temp\L1.DAT"
    sSrcFilePath = ActiveWorkbook.Path & "\Test55260Lines.txt" 'Путь к файлу для переработки
    'sSrcFilePath = ActiveWorkbook.Path & "\L1.DAT"
 
' Путь к переработанный и импортируемый файл - путь тот же - меняем расширение на "csv"
    sNewCSVFilePath = Mid(sSrcFilePath, 1, InStrRev(sSrcFilePath, ".")) & "csv"
 
' Переделка исходного файла в "нормальный" CSV:
    Call TransformFileCSV_RU(sSrcFilePath, sNewCSVFilePath)
    
    sglTimerEnd = Timer 'Timer промежуточный
    
    Debug.Print "Продолжительность переделки файла: " & ElapsedTimeInSec(sglTimerStart, sglTimerEnd) ', datEnd
 
'Создание или Зачистка Листа 2:
    If ActiveWorkbook.Sheets.Count = 1 Then
        Set objSheet = ActiveWorkbook.Sheets.Add(After:=ActiveWorkbook.Worksheets(1))
    Else
        Set objSheet = ActiveWorkbook.Sheets(2) ':  objSheet.UsedRange.Clear
    End If
    objSheet.Name = "ImportTest_05"
 
' Импорт sNewCSVFilePath на objSheet.Range("A1")
    Set objQTable = objSheet.QueryTables.Add( _
                    Connection:="TEXT;" & sNewCSVFilePath, Destination:=objSheet.Range("A1"))
   With objQTable
        .Name = "importCSV"
        .TextFileParseType = xlDelimited
        .AdjustColumnWidth = True
        .TextFileCommaDelimiter = False     '  Запятая
        .TextFileSemicolonDelimiter = False  ' Точка с запятой
        .TextFileTabDelimiter = True         ' TAB
        .TextFileDecimalSeparator = "."      ' Делитель целой и дробной = "."
        .Refresh
        .Delete
    End With
    
    Set objQTable = Nothing
    Set objSheet = Nothing
 
'---------------------------------------------------------------------------------------------------
    sglTimerEnd = Timer 'Timer окончательный
    Debug.Print "Общая продолжительность импорта:" & ElapsedTimeInSec(sglTimerStart, sglTimerEnd)
    
End Sub
 
Private Sub TransformFileCSV_RU(sFilePath$, sNewFilePath$)
' Построчное чтение текстового файла с записью МОДИФИЦИРОВАННЫХ строк в файл: sNewFilePath
'---------------------------------------------------------------------------------------------------
' Модификация строк:
'   01. Очистка строки от не распознаваемых символов (только первая строка заголовка)
'   03. Первые 8 символов строк данных (N строки > 1) - к формату "dd.mm.yy" (вместо "dd-mm-yy")
'   04. У всех строк данных (N строки > 1) - меняем все "." на "," (Делитель целой и дробной)
'---------------------------------------------------------------------------------------------------
Dim FSO As Object, FSOFile As Object, FSOFileNew As Object, TextStream As Object
Dim sVal$, iVal, sDate$, lLine&
Dim sChr$, sText$
'---------------------------------------------------------------------------------------------------
On Error GoTo TransformFileCSV_RU_Err
   
   Set FSO = CreateObject("Scripting.FileSystemObject")
   Set FSOFile = FSO.GetFile(sFilePath)
   Set TextStream = FSOFile.OpenAsTextStream(1) 'OpenFileForReading = 1
   Set FSOFileNew = FSO.CreateTextFile(sNewFilePath, True)
   
    Do While Not TextStream.AtEndOfStream
        lLine = lLine + 1
        sVal = TextStream.ReadLine
        'sVal = Replace(sVal, vbTab, ";", vbTextCompare) 'Змена разделителя (Delimiter)
        If lLine = 1 Then
            sText = "" 'Очистка строки - только первая строка заголовка
            For iVal = 1 To Len(sVal)
                sChr = Mid(sVal, iVal, 1)
                If AscW(sChr) > 0 Then
                   sText = sText & sChr
                End If
            Next iVal
            sVal = sText
        End If
        FSOFileNew.WriteLine sVal ' Запись  строчки в новый файл
    Loop
 
TransformFileCSV_RU_End:
    On Error Resume Next
    TextStream.Close:  Set TextStream = Nothing
    FSOFile.Close:     Set FSOFile = Nothing
    FSOFileNew.Close:  Set FSOFileNew = Nothing
    Set FSO = Nothing: DoEvents
    Err.Clear
    Exit Sub
 
TransformFileCSV_RU_Err:
    MsgBox "Error " & Err.Number & " (" & Err.Description & ") in Sub : " & _
           "TransformFileCSV_RU - modParseOrders.", vbCritical, "Error!"
    Err.Clear
    Resume TransformFileCSV_RU_End
End Sub
 
 
Private Function ElapsedTimeInSec(sglTimerStart As Single, Optional ByVal sglTimerEnd!, _
                                  Optional blnLongFormat As Boolean) As String
' Функция рассчитывает разницу между таймерами с точностью до миллисекунд
' Возвращает отформатированную строку продолжительности формата: "# ##0.000"
' -------------------------------------------------------------------------------------------------/
'Пример эксплуотации:
'Dim sglTimerStart! 'As Single, sglTimerEnd! ( sglTimerEnd - опционально)
'    sglTimerStart = Timer ' Timer начала (дробные секнды (Single) прошедшие с начала суток)
'    ' инструкции ...
'    Debug.Print "Продолжительность до метки ... :" & ElapsedTimeInSec(sglTimerStart)
'    sglTimerEnd = Timer 'Timer окончательный
'    ' ещё инструкции ...
'    Debug.Print "Общая продолжительность:" & ElapsedTimeInSec(sglTimerStart, sglTimerEnd)
' -------------------------------------------------------------------------------------------------/
 
Dim sglTookSeconds!, iVal%
Const csglSecondsPerDay As Single = 86400 'секунд в сутках
    If sglTimerEnd = 0 Then sglTimerEnd = Timer
    If sglTimerEnd < sglTimerStart Then ' Перевод даты на замере (86400 = секунд в сутках)
        sglTookSeconds = (csglSecondsPerDay - sglTimerStart) + sglTimerEnd
    Else
        sglTookSeconds = sglTimerEnd - sglTimerStart 'Проделжительность в секундах (дробное)
    End If
    If blnLongFormat = False Then
        ElapsedTimeInSec = Format(sglTookSeconds, "# ##0.000") & " сек."
    Else ' Длинный формат : "HH:NN:SS.000"
        ElapsedTimeInSec = "допишу потом ..."
     End If
End Function