Поменять значение ячейки и примечания к ней местами в excel?

Sub Поменять_значения_примечания()
    Dim Ce As Range, Temp
    For Each Ce In ActiveSheet.UsedRange.Cells
        With Ce
            If Not .Comment Is Nothing Then
                Temp = .NoteText
                .NoteText .Value
                .Value = Temp
            End If
        End With
    Next
End Sub

Sub Поменять_значения_примечания2()
    Dim Ce As Range
    Dim commText As String, partText As String
    Dim i As Long
 
    'For Each Ce In ActiveSheet.UsedRange.Cells
    For Each Ce In Selection.Cells 'для удобства тестирования
        i = 0
        commText = ""
        If Not Ce.Comment Is Nothing Then
            partText = Ce.NoteText
            While partText <> ""
                commText = commText & partText
                i = i + 1
                partText = Ce.NoteText(, i * 255 + 1)
            Wend
            
            i = 0
            'Вместо этого можно очистить примечание, если способ найдется
            Ce.Comment.Delete
            Ce.AddComment ""
            
            While Len(Ce.value) >= i * 255
                partText = Mid(Ce.value, i * 255 + 1, 255)
                Ce.NoteText partText, i * 255 + 1, 255
                i = i + 1
            Wend
 
            Ce.value = commText
            
            Ce.Comment.Shape.TextFrame.AutoSize = True
        End If
    Next
    'Selection.Rows.AutoFit 'Включить, если высота строки не будет уменьшаться
End Sub