Заполнить два массива случайными числами, вычислить их произведение

Sub P1()
'Чтобы 2 массива можно было переможножить,
'надо чтобы число столбцов первого массива
'совпало с числом строк во втором массиве.
Dim Массив1(1 To 3, 1 To 4) As Integer
Dim Массив2(1 To 4, 1 To 5) As Integer
'Результатом умножения будет третий массив.
Dim Массив3(1 To 3, 1 To 5) As Integer
'Переменные для работы с массивами.
Dim i As Integer, j As Integer, k As Integer
'Массивы для наглядности будем выводить в Excel,
'поэтому очистим лист Excel от прежних массивов.
Cells.Clear
'Randomize - используется, чтобы при каждом запуске
'процедуры генерировалась новая последовательность
'случайных чисел.
Randomize
'Заполнение и вывод в Excel массива Массив1.
For i = 1 To 3 Step 1
    For j = 1 To 4 Step 1
        'Заполнять буду случайными целыми числами
        'в диапазоне от -50 до +50.
        Массив1(i, j) = Int((50 - (-50) + 1) * Rnd + (-50))
        Cells(i, j).Value = Массив1(i, j)
    Next j
Next i
'Заполнение и вывод в Excel массива Массив2.
For i = 1 To 4 Step 1
    For j = 1 To 5 Step 1
        Массив2(i, j) = Int((50 - (-50) + 1) * Rnd + (-50))
        'Расположу Массив2 справа от Массив1.
        'UBound(Массив1, 2) - означает количество столбцов в  Массив1.
        Cells(i, j + UBound(Массив1, 2) + 1).Value = Массив2(i, j)
    Next j
Next i
'Собственно решение задачи: перемножение массивов.
'Перемножаем элементы каждой строки Массив1 с
'элементами каждого столбца Массив2. Все призведения
'двух элементов складываем вместе и получем элемент Массив3.
For i = 1 To UBound(Массив1, 1) Step 1
    For j = 1 To UBound(Массив2, 2) Step 1
        For k = 1 To UBound(Массив1, 2) Step 1
            Массив3(i, j) = Массив3(i, j) + Массив1(i, k) * Массив2(k, j)
        Next k
    Next j
Next i
'Вывод Массив3 в Excel под двумя массивами.
For i = 1 To UBound(Массив3, 1) Step 1
    For j = 1 To UBound(Массив3, 2) Step 1
        Cells(i + UBound(Массив2, 1) + 1, j).Value = Массив3(i, j)
    Next j
Next i
End Sub