Помогите с макросом

Sub Процедура1()
Dim Лист As Excel.Worksheet
Dim Низ As Long
Dim Найдено As Excel.Range, Адрес As String
Dim Подсчёт As Double
'Обращаться к листу с данными будем через переменную Лист
'(так удобнее и кода меньше писать).
'Активной должна быть наша книга, а лист с данными
'должен называться Кабельный журнал.
Set Лист = ActiveWorkbook.Worksheets("Кабельный журнал")
'Определение последней заполненной ячейки в столбце K
'(чтобы все ячейки не просматривать в столбце
'(чтобы код быстрее работал)).
Низ = Лист.Cells(Лист.Rows.Count, "K").End(xlUp).Row
'Поиск и подсчёт ячеек, имеющих цвет 255
'(цвет, который используется в файле, выложенном на форуме).
'Т.к. поиск зависит от диалогового окна Найти и заменить, то
'надо очистить это диалоговое окно от формата.
Application.FindFormat.Clear
'Устанавливаю в диалоговом окне Найти и заменить цвет,
'который буду искать.
Application.FindFormat.Interior.Color = 255
'Собственно поиск и подсчёт.
With Лист.Range(Cells(2, "K"), Cells(Низ, "K"))
    'After - это ячейка, после которой нужно вести поиск.
    'Поиск нужно вести с конца, т.к. поиск начинается после
    'первой ячейки заданного диапазона для поиска.
    Set Найдено = .Find(what:="", After:=Лист.Cells(Низ, "K"), LookIn:=xlFormulas, _
        LookAt:=xlPart, SearchOrder:=xlByColumns, _
        SearchDirection:=xlNext, MatchCase:=False, SearchFormat:=True)
    If Not Найдено Is Nothing Then
        Адрес = Найдено.Address
        Do
            Подсчёт = Подсчёт + Найдено.Value
            If Подсчёт = 1256 Or Подсчёт > 1256 Then
                Лист.Cells(2, "Q").Value = Лист.Cells(2, "Q").Value + 1
                Подсчёт = 0
            End If
            'Для цикла поиска в справке написано, что надо
            'использовать FindNext, но он не работает с форматированием,
            'поэтому буду использовать Find.
            'After - после найденной ячейки.
            Set Найдено = .Find(what:="", After:=Найдено, LookIn:=xlFormulas, _
                LookAt:=xlPart, SearchOrder:=xlByColumns, _
                SearchDirection:=xlNext, MatchCase:=False, SearchFormat:=True)
        Loop While Найдено.Address <> Адрес
        'Определение пригодности для 25-ки.
        If Подсчёт <= 491 And Лист.Cells(2, "Q").Value <> 0 Then
            Лист.Cells(2, "Q").Value = Лист.Cells(2, "Q").Value - 1
            Лист.Cells(3, "Q").Value = 1
        ElseIf Подсчёт <= 491 And Лист.Cells(2, "Q").Value = 0 Then
            Лист.Cells(3, "Q").Value = 1
        End If
    End If
End With
'Очищаем диалоговое окно Найти и заменить от цвета.
Application.FindFormat.Clear
'Просто сообщение, что всё готово.
MsgBox "Работа сделана", vbInformation
End Sub