Подсчитать, сколько различных символов встречается в строке

Sub bb()
Dim s$, i&
s = "Дана строка. Подсчитать, сколько различных символов встречается в ней."
On Error Resume Next
With CreateObject("scripting.dictionary")
    For i = 1 To Len(s)
        .Add Mid$(s, i, 1), "0"
    Next
    MsgBox "Различных символов: " & .Count & vbLf & Join(.keys, "")
End With
End Sub

Sub bb()
Dim s$, i&
s = "Дана строка. Подсчитать, сколько различных символов встречается в ней."
With CreateObject("scripting.dictionary")
    .CompareMode = 1 '1 - не различать регистр. 0 или не задано - различать регистр.
    For i = 1 To Len(s)
        .Item(Mid$(s, i, 1)) = ""
    Next
    MsgBox "Различных символов: " & .Count & vbLf & Join(.keys, "")
End With
End Sub

Sub Символы_строки()
 
Dim S$, C$, I$
Dim N&, L&, L2&
    
    S = InputBox("Введите строку:")
    L = Len(S) ' длина
    I = "" ' результат
    N = 0 ' счетчик
    Do While L > 0
        N = N + 1
        C = Left(S, 1) ' первый символ
        S = Replace( _
                Expression:=S, _
                Find:=C, _
                Replace:="", _
                Start:=1, _
                Count:=-1, _
                Compare:=VBA.vbBinaryCompare)
        L2 = Len(S)
        I = I & VBA.vbLf & CStr(N) & ". """ & C & """ - " & CStr(L - L2)
        L = L2
    Loop
    MsgBox "Номер. Символ - Количество: " & I
 
End Sub