Найти минимальный элемент массива и поменять его местами с первым элементом массива

Sub Процедура1()
    'Указываем, что наш массив будет
    'содержать только целые числа (есть ещё дробные) - As Integer.
    Dim A() As Integer
    'Создаём в оперативной памяти компьютера поименованную область N,
    'которая может содержать только целые числа.
    Dim N As Integer
    Dim i As Integer
    Dim minValue As Integer, minItem As Integer
    Dim intСтол As Integer
    'С помощью InputBox помещаем в переменную N число -
    'количество элементов в массиве.
    N = InputBox("Укажите количество элементов в массиве.")
    'Создаём в оперативной памяти компьютера поименованную область A.
    '1 To - используется, чтобы порядковый номер первого элемента массива
    'был один, а не ноль (по умолчанию ноль), чтобы было удобно.
    ReDim A(1 To N)
    'Заполняем массив числами (чтобы было с чем работать).
    'Числа будем генерировать случайно с помощью Rnd.
    'Диапазон от -100 до +100.
    'For ... To ... Step ... Next - это цикл, который используется
    'для выполнения одного и того же действия заданное количество раз.
    For i = 1 To N Step 1
        'Случайные целые (недробные) числа генерируем по формуле,
        'которая есть в Справке (чтобы посмотреть эту формулу в Справке,
        'поставьте курсор на Rnd и нажмите клавишу F1).
        A(i) = Int((100 - (-100) + 1) * Rnd + (-100))
    Next i
    'Полученный массив для наглядности выводим в Excel.
    For i = 1 To N Step 1
        Cells(i, 1).Value = A(i)
    Next i
    'Собственно решение задачи.
    'Сначала за минимальный элемент принимаем первый элемент массива,
    'а затем остальные элементы массива сравнимаем с ним.
    'В minValue помещаем число из элемента массива.
    minValue = A(1)
    'В minItem помещаем порядковый номер элемента массива.
    minItem = 1
    For i = 2 To N Step 1
        'С помощь If ... Then ... End If - выбираем действие.
        'Если число в элементе меньше числа в переменной minValue,
        'то помещаем число из этого элемента в переменную minValue,
        'а порядковый номер элемента помещаем в переменную minItem.
        If A(i) < minValue Then
            minValue = A(i)
            minItem = i
        End If
    Next i
    'Теперь перемещаем число из первого элемента массива в элемент массива,
    'в котором содержится самое маленькое число и наоборот.
    'Для этого нужно использовать дополнительную переменную intСтол,
    'в которую поместим число из первого элемента массива.
    intСтол = A(1)
    A(1) = A(minItem)
    A(minItem) = intСтол
    'Выводим изменённый массив в Excel для наглядности
    '(чтобы проверить - правильно ли у нас работает код).
    For i = 1 To N Step 1
        Cells(i, 2).Value = A(i)
    Next i
End Sub

Sub n()
    Cells.Clear
    Randomize
    kol = InputBox("Введите к-во эл-тов", , 10)
    Set Rng = Range(Cells(1, 1), Cells(kol, 1))
    Rng.Formula = "=int(rand()*30+1)"
    Rng.Value = Rng.Value
    [b1] = "массив до замены"
     With Application.WorksheetFunction
      nom_min = .Match(.Min(Rng), Rng, 0)
      MsgBox "Номер минимального эл-та=" & nom_min
     End With
    'замена
     temp = [a1]
     [a1] = Range("A" & nom_min)
     Range("A" & nom_min) = temp
     [b1] = "массив после замены"
     MsgBox "Замена произведена!!!"
End Sub