Рекурсия: На шахматной доске расставить 8 ферзей так, чтобы они не били друг друга

Option Explicit
Const cntQueens = 8 'Количество ферзей (или размер доски)
Dim H(cntQueens - 1) As Integer 'горизонталь для каждого ферзя
 
Sub Queens()
'Erase H
Решение 0
End Sub
 
Sub Решение(W As Integer)
Dim I As Integer, J As Integer
For H(W) = 0 To cntQueens - 1
  For I = 0 To W - 1
    If H(I) = H(W) Or Abs(H(I) - H(W)) = W - I Then 'ферзи бьют друг друга
      Exit For 'идём вверх, на Next H(W)
    End If
  Next I
  If I = W Then 'ферзи не бьют друг друга
    If W = cntQueens - 1 Then 'ферзь последний
      For I = 0 To cntQueens - 1 'вывод результата
        Debug.Print Chr$(65 + I) & H(I) + 1 & " ";
      Next I
      Debug.Print
    Else 'ферзь не последний
      Решение W + 1 'идём к следующему
    End If
  End If
Next H(W)
H(W) = 0
End Sub

Option Explicit
Const cntQueens = 8 'Количество ферзей (или размер доски)
Dim H(1 To cntQueens) As Integer 'горизонталь для каждого ферзя
Dim chessMap As Range
Dim R As Long
 
Sub Queens()
'Erase H
Cells.Clear
Cells.Font.Size = 36
Cells.HorizontalAlignment = xlCenter
Cells.VerticalAlignment = xlCenter
Cells.RowHeight = 40
Cells.ColumnWidth = 6.86
Cells(1).Activate
R = 1
Решение 1
End Sub
 
Sub Решение(W As Integer)
Dim I As Integer
For H(W) = 1 To cntQueens
  For I = 1 To W - 1
    If H(I) = H(W) Or Abs(H(I) - H(W)) = W - I Then 'ферзи бьют друг друга
      Exit For 'идём вверх, на Next H(W)
    End If
  Next I
  If I = W Then 'ферзи не бьют друг друга
    If W = cntQueens Then 'ферзь последний
      Set chessMap = Range(Cells(R, 1), Cells(R + cntQueens - 1, cntQueens))
      With chessMap
        .Borders(xlEdgeLeft).LineStyle = xlContinuous
        .Borders(xlEdgeTop).LineStyle = xlContinuous
        .Borders(xlEdgeBottom).LineStyle = xlContinuous
        .Borders(xlEdgeRight).LineStyle = xlContinuous
      End With
      For I = 1 To cntQueens
         Cells(cntQueens - H(I) + R, I) = ChrW(9819)
      Next I
      R = R + cntQueens + 1
    Else 'ферзь не последний
      Решение W + 1 'идём к следующему
    End If
  End If
Next H(W)
End Sub

Type myType
    i() As Long
    s As String
End Type
 
Sub bb()
Dim x(0 To 4) As myType
ReDim x(1).i(0 To 2)
For x(1).i(0) = 1 To 3
    Debug.Print x(1).i(0)
Next
End Sub

For ActiveCell.Value = 1 To 3 'не компилируется!

Sub bb()
Dim v(0 To 2)
Dim r(4 To 6) As Object
 
For Each v(1) In Split("мама мыла раму")
    Debug.Print v(1)
Next
 
For Each r(5) In [A1:A5]
    Debug.Print r(5).Address
Next
End Sub

Sub vv()
Dim i&(), chk&
ReDim i(1 To 2, 1 To 1)
For i(2, 1) = 1 To 1000000
    chk = chk + 1
    If i(2, 1) Mod 2 Then ReDim Preserve i(1 To 2, 1 To UBound(i, 2) + 1)
    If i(2, 1) <> chk Then Stop
Next
End Sub