Найти наименьший из положительных элементов массива

Sub Procedure_1()
    
    '1. Создаём на пластинках оперативной памяти поименованную область: массив.
    '2. Задаём размер массива. Размер массива - это количество чисел в массиве.
        '1 To 20 означает, что в массиве будет 20 элементов.
        '1 To используется, чтобы порядковый номер первого элемента массива был
        'один. Если не указывать 1 To, то порядковый номер первого элемента
        'массива будет ноль, что неудобно непрограммистам.
    '3. Указываем, какой тип данных у нас будет в массиве.
        'Long - означает, что в переменной могут быть только целые числа
        '(есть ещё дробные).
    Dim x(1 To 20) As Long
    
    'Создаём на пластинках оперативной памяти компьютера различные
    'поименованные области - переменные, которые нам понадобятся
    'для решения различных задач.
    Dim i As Long
    Dim minItem As Long, minValue As Long
    
    'Заполняем массив числами, чтобы было с чем работать.
    'Чтобы не выдумывать 20 чисел, будем использовать генератор
    'случайных чисел - Rnd, который будет генерировать случайные числа.
    
    'For ... To ... Step ... Next - называется циклом и используется для
    'выполнения одного и того же действия заданное количество раз.
    For i = 1 To 20 Step 1
        'Генерировать буду целые числа от -100 до +100.
        'Чтобы посмотреть формулу, по которой генерировать случайные
        'целые числа, поставьте курсор на слово Rnd и нажмите клавишу
        'F1, откроется справка, в которой есть формула.
        x(i) = Int((100 - (-100) + 1) * Rnd + (-100))
    Next i
    
    'Чтобы проверить работу кода, а именно, что у нас находится в массиве,
    'выведем содержимое массива на активный лист Excel.
    For i = 1 To 20 Step 1
        ActiveSheet.Cells(i, "A").Value = x(i)
    Next i
    
    'Собственно решение поставленной задачи.
    
    '1. Находим первый положительный элемент в массиве.
        'Затем будем его сравнивать с остальными положительными элементами.
    For i = 1 To 20 Step 1
        'If ... Then ... End If - используется для выбора действия.
        If x(i) > 0 Then
            'Запоминаем порядковый номер элемента массива и число, которое
            'находится в нём.
            minItem = i
            minValue = x(i)
            'Выходим из цикла, т.к. задачей было найти первый положительный
            'элемент и нет смысла просматривать остальные элементы массива.
            Exit For
        End If
    Next i
    
    '2. Теперь находим наименьший положительный элемент в массиве.
    For i = 1 To 20 Step 1
        'Если очередной элемент положительный и меньше числа,
        'которое находится в переменной minValue, то
        'помещаем в переменную minValue число из этого элемента.
        'И затем остальные элементы уже сравниваем с новым числом.
        If x(i) > 0 And x(i) < minValue Then
            minItem = i
            minValue = x(i)
        End If
    Next i
    
    'С помощью MsgBox отображаем на мониторе результат.
    'Символ & соединяет фрагменты в одну строку.
    'vbCr переносит текст на следующую строку.
    MsgBox "Порядковый номер: " & minItem & vbCr & "Значение: " & minValue
    
End Sub