Как искать и перемещать данные на новый (уже существующий) лист

Sub Макрос1()
    
    'Здесь указываем, что нужно искать.
    Const lSearchText As Double = 5
    
    Dim shSheet_1 As Excel.Worksheet
    Dim shSheet_2 As Excel.Worksheet
    
    Dim lLastRowSheet_1 As Long
    Dim lLastRowSheet_2 As Long
    Dim i As Long
    
    'Для удобства написания кода будем обращаться к нужным листам
    'по именам shSheet_1 и shSheet_2.
    Set shSheet_1 = Worksheets(1)
    Set shSheet_2 = Worksheets(2)
    
    
    'Определение последних заполенных строк на двух листах.
    
    '1. Для первого листа это нужно, чтобы знать с какой ячейки начать двигаться вверх.
        'Если двигаться с самой последней ячейки в столбце, то будет долго.
    
    'Действие аналогичное тому, если сделать активной последнюю ячейку
    'в столбце A и нажать сочетание клавиш Ctrl + стрелка вверх.
    lLastRowSheet_1 = shSheet_1.Cells(shSheet_1.Rows.Count, "A").End(xlUp).Row
    
    '2. Для второго листа последняя строка с данными определяется, чтобы знать,
        'куда вставлять данные.
    lLastRowSheet_2 = shSheet_2.Cells(shSheet_2.Rows.Count, "A").End(xlUp).Row + 1
    
    
    'Отключение обновление монитора, чтобы код быстрее работал.
    Application.ScreenUpdating = False
    
    'Когда нужно удалить строку на листе, то чтобы было проще,
    'нужно идти снизу листа вверх.
    For i = lLastRowSheet_1 To 1 Step -1
        'Если в ячейке содержится искомый текст.
        If shSheet_1.Cells(i, "A").Value = lSearchText Then
        
            'Переносим строку на второй лист.
            'Я так понял, что нельзя вырезать строку с одновременным её удалением.
            'Поэтому не знаю, зачем использовать в этом случае метод Cut.
            'Буду использовать метод Copy.
            shSheet_1.Rows(i).Copy Destination:=shSheet_2.Rows(lLastRowSheet_2)
            
            'Удаление строки.
            shSheet_1.Rows(i).Delete Shift:=xlShiftUp
            
            'Задаём новый номер строки на втором листе, куда вставлять данные.
            lLastRowSheet_2 = lLastRowSheet_2 + 1
            
        End If
    Next i
 
    'Сообщение, что работа кода завершена.
    MsgBox "Работа кода завершена.", vbInformation
    
    'Включение обновления монитора.
    Application.ScreenUpdating = True
    
End Sub

'Переносим данные из текущей строки на второй лист.
shSheet_2.Rows(lLastRowSheet_2).Value = shSheet_1.Rows(i).Value

Sub Макрос1()
    
    Dim shSheet_1 As Excel.Worksheet
    Dim shSheet_2 As Excel.Worksheet
    Dim dSearchText(1 To 3) As Double
    Dim dCellText As Double
    Dim lLastRowSheet_1 As Long
    Dim lLastRowSheet_2 As Long
    Dim i As Long, j As Long
    
    'Указываем числа, которые надо найти.
    dSearchText(1) = 2
    dSearchText(2) = 3
    dSearchText(3) = 5
    
    'Для удобства написания кода будем обращаться к нужным листам
    'по именам shSheet_1 и shSheet_2.
    Set shSheet_1 = Worksheets(1)
    Set shSheet_2 = Worksheets(2)
    
    
    'Определение последних заполенных строк на двух листах.
    
    '1. Для первого листа это нужно, чтобы знать с какой ячейки начать двигаться вверх.
        'Если двигаться с самой последней ячейки в столбце, то будет долго.
    
    'Действие аналогичное тому, если сделать активной последнюю ячейку
    'в столбце A и нажать сочетание клавиш Ctrl + стрелка вверх.
    lLastRowSheet_1 = shSheet_1.Cells(shSheet_1.Rows.Count, "A").End(xlUp).Row
    
    '2. Для второго листа последняя строка с данными определяется, чтобы знать,
        'куда вставлять данные.
    lLastRowSheet_2 = shSheet_2.Cells(shSheet_2.Rows.Count, "A").End(xlUp).Row + 1
    
    
    'Отключение обновление монитора, чтобы код быстрее работал.
    Application.ScreenUpdating = False
    
    'Когда нужно удалить строку на листе, то чтобы было проще,
    'нужно идти снизу листа вверх.
    For i = lLastRowSheet_1 To 1 Step -1
    
        'Проверяем, что в ячейке число, а не текст, чтобы не было ошибки.
        If IsNumeric(shSheet_1.Cells(i, "A").Value) = True Then
        
            'Чтобы каждый раз не обращаться к ячейке, т.к. это долго,
            'помещаем данные из ячейки в переменную.
            dCellText = shSheet_1.Cells(i, "A").Value
        
            'Просматриваем элементы массива, в котором содержатся
            'числа, которые нужно найти.
            For j = 1 To UBound(dSearchText) Step 1
                
                'Если есть совпадение.
                If dSearchText(j) = dCellText Then
                
                    'Переносим данные из текущей строки на второй лист.
                    shSheet_2.Rows(lLastRowSheet_2).Value = shSheet_1.Rows(i).Value
                    'Удаление строки.
                    shSheet_1.Rows(i).Delete Shift:=xlShiftUp
                    
                    'Задаём новый номер строки на втором листе, куда вставлять данные.
                    lLastRowSheet_2 = lLastRowSheet_2 + 1
                    
                    'Выходим из цикла просмотра массива dSearchText.
                    Exit For
                    
                End If
                
            Next j
        
        End If
            
    Next i
 
    'Сообщение, что работа кода завершена.
    MsgBox "Работа кода завершена.", vbInformation
    
    'Включение обновления монитора.
    Application.ScreenUpdating = True
    
End Sub