Реализация алгоритма сортировки слиянием

Option Explicit
 
 
' Тестирование сортировки - запускать эту процедуру
Sub test()
    Dim i As Long, A(1 To 65536) As Double
    
    ' Заполнить массив случайными числами от 0 до 1
    Randomize
    i = 1
    Do While i <= UBound(A)
        A(i) = Rnd()
        i = i + 1
    Loop
    
    ' Запуск сортировки слиянием
    Call MergeSort(A)
    
    ' Вывести массив на лист
    ' Две строки ниже немного ускорят вывод в Excel:
    Application.ScreenUpdating = False
    Application.EnableEvents = False
    With Worksheets(1) ' Вывод в первый лист книги
        i = 1
        Do While i <= UBound(A)
            .Cells(i, 1) = A(i) ' Вывод в первый столбец книги
            i = i + 1
        Loop
    End With
    ' Две строки ниже восстановят нормальный режим работы Excel:
    Application.ScreenUpdating = True
    Application.EnableEvents = True
End Sub
 
 
' Рекурсивная сортировка слиянием
Private Sub MergeSort(A() As Double)
    Dim B() As Double, C() As Double, i As Long, j As Long
    Dim m As Long, n As Long, k As Long, l As Long
    
    m = UBound(A) ' Размерность основного массива
    ' Условие продолжения рекурсии m > 1, так как
    ' массив из одного элемента уже отсортирован :)
    If m > 1 Then
        ' Получить первую часть массива
        n = m \ 2 ' Размерность первой части массива
        ReDim B(1 To n)
        For i = 1 To n
            B(i) = A(i)
        Next i
        Call MergeSort(B) ' Отсортировать (рекурсия)
        
        ' Получить вторую часть массива
        k = m - n ' Размерность второй части массива
        ReDim C(1 To k)
        For i = 1 To k
            C(i) = A(n + i)
        Next i
        Call MergeSort(C) ' Отсортировать (рекурсия)
        
        ' Слить два отсортированных массива в основной
        i = 1 ' Счетчик первой части массива
        j = 1 ' Счетчик второй части массива
        l = 1 ' Счетчик основного массива
        Do While i <= n And j <= k
            If B(i) < C(j) Then
                A(l) = B(i)
                i = i + 1
            Else
                A(l) = C(j)
                j = j + 1
            End If
            l = l + 1
        Loop
        ' Дописать в массив невключенные "остатки"
        Do While i <= n ' От первой части массива
            A(l) = B(i)
            i = i + 1
            l = l + 1
        Loop
        Do While j <= k ' От второй части массива
            A(l) = C(j)
            j = j + 1
            l = l + 1
        Loop
    End If
End Sub