Как в матрице удалить каждый пятый столбец

Sub Procedure_1()
 
    'Создаём матрицу lMatrix_1, у которой 10 строк и 15 столбцов.
    Dim lMatrix_1(1 To 10, 1 To 15) As Long
    Dim lMatrix_2() As Long
    Dim lColumnsDelete As Long
    Dim i As Long, j As Long, k As Long
    
    'Определяем, сколько останется столбцов во второй матрице.
    'UBound(lMatrix_1, 2) - это количество столбцов в матрице.
    'С помощью Int берём целое число из дробного числа.
    lColumnsDelete = Int(UBound(lMatrix_1, 2) / 5)
    
    'Задаём размер у матрицы lMatrix_2.
    ReDim lMatrix_2(1 To 10, 1 To UBound(lMatrix_1, 2) - lColumnsDelete)
    
    'Заполянем первую матрицу случайными числами, чтобы было с чем работать.
    For i = 1 To UBound(lMatrix_1, 1) Step 1
        For j = 1 To UBound(lMatrix_1, 2) Step 1
            'Генерируются целые числа от -50 до +50.
            lMatrix_1(i, j) = Int((50 - (-50) + 1) * Rnd) + (-50)
        Next j
    Next i
    
    'Выводим матрицу в Excel, чтобы видеть, что за матрица.
    Worksheets(1).Range("A1").Resize(UBound(lMatrix_1, 1), UBound(lMatrix_1, 2)).Value = _
        lMatrix_1()
 
    'Переносим данные из одной матрицы в другую
    'кроме пятых столбцов.
    'k - используется для движения по столбцам во второй матрице.
    k = 1
    'С помощью j двигаемся по столбцам.
    For j = 1 To UBound(lMatrix_1, 2) Step 1
    
        'Если это пятый столбец, то пропускаем его.
        If j Mod 5 = 0 Then
            GoTo metka
        End If
        
        'С помощью i двигаемся по строкам.
        For i = 1 To UBound(lMatrix_1, 1) Step 1
            lMatrix_2(i, k) = lMatrix_1(i, j)
        Next i
        
        'Переход к следующему столбцу во второй матрице.
        k = k + 1
        
metka:
        
    Next j
    
    'Выводим вторую матрицу на второй лист, чтобы посмотреть результат работы кода.
    Worksheets(2).Range("A1").Resize(UBound(lMatrix_2, 1), UBound(lMatrix_2, 2)) = _
        lMatrix_2()
 
End Sub