Скрипт очистки (перевести с Batch на VBScript)

Set oShell = CreateObject("WScript.Shell")
SysDisk = oShell.ExpandEnvironmentStrings("%SystemDrive%")
ProgramFiles = oShell.ExpandEnvironmentStrings("%ProgramFiles%")
MozillaLog = LCase(ProgramFiles & "\Mozilla Firefox\uninstall\uninstall.log")
TotalSize = 0
 
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oSysDrive = oFSO.GetDrive(SysDisk)
Set oFolder = oSysDrive.RootFolder
 
ScanFolder oFolder
 
WScript.Echo "Очищено: " & TotalSize & " Байт."
 
Sub ScanFolder(oFold)
    On Error Resume Next
    Set oFiles = oFold.Files
    If oFold.Attributes >= 1024 Then Exit Sub 'проходим мимо симлинков
    
    For Each oFile In oFiles
        ext = LCase(oFSO.GetExtensionName(oFile.Path))
 
        if ext = "log" or ext = "temp" or ext = "tmp" then
            if not (Lcase(Left(oFile.Name, 3)) = "v01" and ext = "log") then
                if LCase(oFile.Path) <> MozillaLog then
                    iSize = oFile.Size
                    oFile.Delete(true)
                    if Err.Number = 0 then TotalSize = TotalSize + iSize else Err.Clear
                end if
            end if
        end if
    Next
 
    Set oFolders = oFold.Subfolders 'рекурсия
    For Each oSubFolder In oFolders
        ScanFolder oSubFolder
    Next
End Sub