Запуск батника из вбс скрипта

Open:\Путь к файлу.....
..........

WshShell.Run """полный путь к батнику"" параметры"

Dim objWShell, strPath1, strPath2, strArg1, strArg2, strArg3
Dim objFS, objFile, strTemp, arrTemp
 
strPath1 = "D:\1.bat"
strPath2 = "D:\args.txt"
Set objFS = CreateObject("Scripting.FileSystemObject")
If objFS.FileExists(strPath1) Then
    If objFS.FileExists(strPath2) Then
        Set objFile = objFS.OpenTextFile(strPath2, 1)
        If objFS.GetFile(strPath2).Size > 0 Then
            strTemp = objFile.ReadAll
            objFile.Close
            Set objFile = Nothing
            arrTemp = Split(strTemp, vbNewLine)
            If UBound(arrTemp) > 1 Then
                If Len(arrTemp(0)) > 0 Then strArg1 = arrTemp(0)
                If Len(arrTemp(1)) > 0 Then strArg2 = arrTemp(1)
                If Len(arrTemp(2)) > 0 Then strArg3 = arrTemp(2)
                Erase arrTemp
                If IsEmpty(strArg1) Or IsEmpty(strArg2) Or IsEmpty(strArg3) Then
                    WScript.Echo "Не все аргументы определены"
                Else
                    Set objWShell = CreateObject("WScript.Shell")
                    objWShell.Run strPath1 & " " & strArg1 & " " & strArg2 & " " & strArg3, 1
                    Set objWShell = Nothing
                End If
            Else
                WScript.Echo "Недостаточно данных"
            End If
        Else
            WScript.Echo "Файл аргументов пуст"
        End If
    Else
        WScript.Echo "Не найден путь " & strPath2
    End If
Else
    WScript.Echo "Не найден путь " & strPath1
End If
Set objFS = Nothing
WScript.Quit 0

Option Explicit
 
Dim Batfile, ArgumentsFile
 
Batfile = "c:\1 1\args.exe"
ArgumentsFile = "h:\_VBA\_Dragokas\CommandLine_Arguments\args.txt"
 
call RunProcess(BatFile, ArgumentsFile)
 
Function RunProcess(strPath1, strPath2)
    Dim objFS, strTemp, argc, argv, CmdLine, n
 
    Set objFS = CreateObject("Scripting.FileSystemObject")
 
    If not objFS.FileExists(strPath1) Then WScript.Echo "Не найден путь " & strPath1: Exit Function
    If not objFS.FileExists(strPath2) Then WScript.Echo "Не найден путь " & strPath2: Exit Function
 
    If objFS.GetFile(strPath2).Size = 0 Then WScript.Echo "Файл аргументов пуст": Exit Function
    With objFS.OpenTextFile(strPath2, 1)
        strTemp = .ReadAll
        .Close
    end with
 
    CmdLine = """" & strPath1 & """"            ' Имя файла в кавычки
    
    If strTemp <> "" Then                       ' Если есть аргументы, их тоже добавляем в кавычках
        Parse_CMD strTemp, argc, argv           ' Вместо CommandLineToArgvW
        For n = 1 To argc
            CmdLine = CmdLine & " """ & argv(n) & """"
        Next
    End If
 
    CreateObject("WScript.Shell").Run CmdLine, 1
    Set objFS = Nothing
End Function
 
Sub Parse_CMD(inCmdLine, argc, argv)
  Dim Lex, St, nL, nA, Unit
  St = inCmdLine 'Command()
  Lex = Split(St) 'Разбиваем по пробелам для лексического анализа
  ReDim argv(UBound(Lex) + 1) 'Определяем выходной массив до максимально возможного числа параметров
  argv(0) = WScript.ScriptFullName
  If Len(St) <> 0 Then
    Do While nL <= UBound(Lex)
      Unit = Lex(nL) 'Записысаем смысловую единицу
      If Len(Unit) <> 0 Then 'Защита от двойных пробелов между параметрами
        If Left(Lex(nL), 1) = """" Then 'Если попалась кавычка
          Do Until Right(Lex(nL), 1) = """" 'Пока не найдем кавычке пару
            nL = nL + 1
            If nL > UBound(Lex) Then Exit Do 'Если не дождались завершающей кавычки, а лимит превышен
            Unit = Unit & " " & Lex(nL)
          Loop
          Unit = Replace(Unit, """", "") 'Удаляем кавычки
        End If
        argv(nA + 1) = Unit
        nA = nA + 1 'Счетчик выходных аргументов
      End If
      nL = nL + 1 'Счетчик лексических единиц
    Loop
  End If
  ReDim Preserve argv(nA)
  argc = nA
End Sub