Печать PDF-файлов из разных папок одной кнопкой

Dim objFS, objShell, strFile, strPath, strArguments, strVerb, intShowMode
strFile = "1.pdf": strArguments = "": strPath = "D:\Temp": strVerb = "print": intShowMode = 0
Set objFS = CreateObject("Scripting.FileSystemObject")
If objFS.FileExists(objFS.BuildPath(strPath, strFile)) Then
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.NameSpace(&h4)
    If objShell.NameSpace(&h4).Items.Count > 1 Then
        On Error Resume Next
        objShell.ShellExecute strFile, strArguments, strPath, strVerb, intShowMode
        If Err.Number = 0 Then
            WScript.Echo "Задание печати обработано успешно."
        Else
            WScript.Echo "Ошибка " & Err.Number & " при обработке задания печати." & vbNewLine & Err.Description
            Err.Clear
        End If
    Else
        WScript.Echo "Не найдено ни одного подключения к принтеру."
    End If
    Set objShell = Nothing
Else
    WScript.Echo "Не найден путь " & objFS.BuildPath(strPath, strFile)
End If
Set objFS = Nothing
WScript.Quit 0

Dim objFS, objShell, objFolderItems
Dim strMask, arrFolders, strArguments, strVerb, intShowMode, strTemp, i, j
 
strMask = "*.pdf": strArguments = "": strVerb = "print": intShowMode = 0
arrFolders = Array("D:\Temp", "E:\Temp")
Set objShell = CreateObject("Shell.Application")
If objShell.NameSpace(&h4).Items.Count > 1 Then
    Set objFS = CreateObject("Scripting.FileSystemObject")
    For i = 0 To UBound(arrFolders)
        If objFS.FolderExists(arrFolders(i)) Then
            Set objFolderItems = objShell.NameSpace(arrFolders(i)).Items
            objFolderItems.Filter 64 + 128, strMask
            On Error Resume Next
            For j = 0 To objFolderItems.Count - 1
                strTemp = objFolderItems.Item(j).Name
                objShell.ShellExecute strTemp, strArguments, arrFolders(i), strVerb, intShowMode
                If Err.Number = 0 Then
                    WScript.Echo "Задание печати файла " & strTemp & " обработано успешно."
                Else
                    WScript.Echo "Ошибка " & Err.Number & " при печати файла " & strTemp & vbNewLine & Err.Description
                    Err.Clear
                End If
            Next
            On Error GoTo 0
        Else
            WScript.Echo "Не найден путь " & arrFolders(i)
        End If
    Next
    Set objFolderItems = Nothing: Set objFS = Nothing
Else
    WScript.Echo "Не найдено ни одного подключения к принтеру."
End If
Set objShell = Nothing
WScript.Quit 0